Fool a process into thinking that STDOUT is a terminal

[etcshadow]

Fool a process into thinking that STDOUT is a terminal, when in fact it may be a file or a pipe.

This can be useful with programs like ps and w on linux... which will trunc their output to the width of the terminal, and, if they cannot detect the terminal width, use a default 80 columns. Wouldn't it be nice to say "ps -aux | grep etcshadow", and get output that looks like when you just say "ps -aux"? Well, that's the idea.

#!/usr/bin/perl -w
# Fools a process into thinking that STDOUT is a terminal,
# when in fact it may be a file or a pipe.
use IO::Pty;
use strict;
die "usage: $0 command [args]\n" unless @ARGV;

my $pty = IO::Pty->new;
my $slave = $pty->slave;
open TTY,"/dev/tty" or die "not connected to a terminal\n";
$pty->clone_winsize_from(\*TTY);
close TTY;

my $pid = fork();
die "bad fork: $!\n" unless defined $pid;
if (!$pid) {
    $slave->close();
    open STDOUT,">&=".$pty->fileno() or die $!;
    exec @ARGV;
}
else {
    $pty->close();
    while (defined (my $line = <$slave>)) {
        print $line;
    }
}