Re: regex logical equivalence?

[Roger]

The good thing about Perl regex is that you don't have to write the entire regex in one go, you can build it part by part programmatically. I often construct my regex in the maner as shown below to improve readability (at least to myself) and maintainability:

use strict;
use warnings;

# allowed prompt characters
my $prompt_regex = '[>$%@~# ]';

# allowed characters in the prompt
my $allowed_regex = '[\w@\-\.]*';

# a list of allowed prompt patterns
my @patterns = (
    '\[?' . $allowed_regex . $prompt_regex . '\]?',
    quotemeta '\\[\\e[0m\\] [0m',
);

# build my regex dynamically
my $regex = '(' . join('|',@patterns) .')\s?';

# test the regex
print "regex: /$regex/\n\n";

while (<DATA>) {
    chomp;
    /$regex/ && printf "%-30smatched: %s\n", $_, $1;
}

__DATA__
[e-mail]# blah
[e-mail]~ crap crap
[roger@www#] blah blah foo
[[e-mail]~] crap crap
\[\e[0m\] [0m foo bar

And the output -

regex: /(\[?[\w@\-\.]*[>$%@~# ]\]?|\\\[\\e\[0m\\\]\ \[0m)\s?/

[e-mail]# blah       matched: [e-mail]#
[e-mail]~ crap crap      matched: [e-mail]~
[roger@www#] blah blah foo    matched: [roger@www#]
[[e-mail]~] crap crap    matched: [[e-mail]~]
\[\e[0m\] [0m foo bar         matched: \[\e[0m\] [0m