Test the syntactic validity of a domain name

[merlyn]

AltBlue wanted to test a given string to see if was syntactically valid as a domain name. Here's the code that was too long to type into the chatterbox.

sub could_be_a_host {
  my @a = split /\./, shift, -1;
  @a > 0 and
    not grep !/^[a-z0-9\-]+$/i, @a and
    not grep /^\d+$/, @a and
    not grep /^-|-$/, @a;
}

or, a slightly faster version:

sub could_be_a_host {
  my @a = split /\./, shift, -1;
  return 0 unless @a;
  for (@a) {
    return 0 unless /^[a-z0-9\-]+$/i;
    return 0 if /^\d+$/;
    return 0 if /^-/;
    return 0 if /-$/;
  }
  1;
}

(Modified slightly per tye's suggestion, thanks!)

[tye]

You forgot that split drops trailing null fields by default. For all but the oldest of perls, you can do the following to fix that:

    my @a= split /[.]/, shift, -1;

        - tye (but my friends call me "Tye")

[japhy]

fixed, updated, whatever...

Randal, could it be sped up via a "must match this" regex?

sub valid_domain {
  return $_[0] =~ m{
    \A
    (?:
      (?!\d+\.)
      [a-zA-Z0-9]+ (?: -+ [a-zA-Z0-9]+ )*
      \.
    )*
    (?!\d+\z)
    [a-zA-Z0-9]+ (?: -+ [a-zA-Z0-9]+ )*
  }x;



$_="goto+F.print+chop;\n=yhpaj";F1:eval

[tye]

Seemed close but allowed "-" as last char of components.

        - tye (but my friends call me "Tye")

[japhy]

I fixed it. I guess I should've done update or something like that, as I've seen in other people's posts.

$_="goto+F.print+chop;\n=yhpaj";F1:eval

[extremely]

Sigh, I hate to party poop this so late but www.411.com is legit and the code above disallows it. More importantly the rules on the third level are a great deal less persnickity than most people think. All kinds of abuses are possible. See DNS Adventure and the legendary URLCalc hack.

--
$you = new YOU;
honk() if $you->love(perl)

[ncw]

It matches newlines at the end of the domain name :-

  print could_be_a_host("www.domain.com\n"); # says 1

\z instead of $ in the regexps would fix it for recent perls as would a judicously placed chomp - but I'm sure you know this already!