There are quite a few techniques you can use to make your regexen nicer, any combination of which might be useful to you, see for example /x, /e, /r, \K, and lookarounds in perlre. In the following example I've thrown all of them together into one, which may be overkill. (I see ikegami has posted something similar, albeit non-functional, while I was composing this.)

my $data = <<'END';
foo123bar
# foo123bar foo456bar
# xyz foo789bar abc
foo456bar
END

$data =~ s{
    ^                 # beginning of line
    \h* \# \h*        # comment lines
    \K                # keep everything up to here in replacement
    (?<comment> \N*)  # capture the comment
    $                 # end of line
} { handle_foobar( $+{comment} ) }msxge;

sub handle_foobar {
    return shift =~ s{
            foo \K (\d+) (?= bar )
        }{
            $1 =~ tr/0-9/a-j/r
        }msxger;
}
[download]

I could turn the string into a line-list

Note it's also possible to open a string as an in-memory filehandle:

my $str = <<'END';
Hello
# START
World
# END
Aaa
# START
Bbb
# END
Ccc
END

open my $fh, '<', \$str or die $!;
while (<$fh>) {
    chomp;
    if ( /^# START/ .. /^# END/ ) {
        print "<$_>\n";
    }
}
close $fh;
[download]

Also, a more advanced regex technique is m/\G.../gc parsing, which is described in perlop. Also, as for your example here, if the delimiters need to be escaped, see Regexp::Common::delimited.