Hello Sascha2018,

See IO::FDPass for passing a handle to a process. Another way is storing the handle into a hash and use $ident as the key. I'm passing $dent to $pm->start($ident). That sets the identification for the process. Inside the on_finish block, remove the entry from the hash.

Well, something like the following. Please adjust the _uid function accordingly, to your specification.

#!/usr/bin/perl

use strict;
use warnings;
use feature 'state';

no strict 'refs';

use IO::Socket;
use IO::Select;
use Parallel::ForkManager;

my $die = 0;
my %lkup;

sub _uid {
    state $uid = 0;
    $uid = 1 if ++$uid > 2e9;
    $uid;
}

$SIG{INT} = sub { $die = 1; exit; };

my %clients = ();
my $select = IO::Select->new;

my $server = IO::Socket::INET->new(
    LocalHost => 'localhost',
    LocalPort => 2222,
    Proto     => 'tcp',
    Listen    => 10000,
    Reuse     => 1,
) or die "Sock Error: $!\n";

my $pm = Parallel::ForkManager->new(10);
$pm->set_waitpid_blocking_sleep(0);

$pm->run_on_finish( sub {
    my ($pid,$exitcode,$ident,$exitsignal,$coredump,$get) = @_;
    $clients{$ident}->{ident}  = $ident;
    $clients{$ident}->{ip}     = $get->{ip};
    $clients{$ident}->{socket} = delete $lkup{$ident};
});

$server->autoflush(1);
$select->add($server);

while (!$die) {
    foreach my $key ($select->can_read()) {  # foreach
        if ($key eq $server) {  # if $bay eq $server
            next if $key eq "";

            my $bay   = $server->accept or next;
            my $ip    = $bay->peerhost();
            my $ident = _uid();

            $lkup{$ident} = $bay;
            $select->add($bay);

            $pm->start($ident) and next;
            select($bay); $| = 1;

            foreach my $client (keys %clients) {
                print "Connection from $clients{$client}->{ip} with Id
+ent $clients{$client}->{ident} and Socket $clients{$client}->{socket}
+ ... OK\n";
            }

            $pm->finish(0, { ip => $ip });
        }
    }

    $pm->wait_all_children;
}

sub sendHeader {
    my $sock = shift;
my $header =<<"EOT";
HTTP/1.0 200 OK
Content-type: text/html
EOT
    $sock->syswrite($header);
}
[download]

Regards, Mario