Now that you've gotten answers to your question, I figured I'll answer the real question and give an answer that you can't easily read yourself to about data structures.

The first and most interesting part is to redesign the data structure. It seems that you want an ordered list and therefore have an array with the columns, but you also want to have several values attached to that value. My suggestion is that you consider having a data structure looking like

my @data = (
    [ Gender => [ 'Male', 'Female'] ],
    [ A => [ 'a', 'b', 'c'] ],
);
[download]

which would remove the need for parallel data structures. Your code would then look like

for (@data) {
    my ($column, $options) = @$_;

    print $column . ': ';
    foreach my $option (@$options) {
        print '<input type="radio" name="' . $column . '" value="' . $
+option . '"> ' . $option . ' ';
    }
}
[download]

As a side note, I think that print statement is more clearly written using printf() and another qoute delimiter:

        printf qq{<input type="radio" name="%s" value="%s">%s\n},
            $column,
            $option,
            $option
        ;
[download]

But really, this is unnecessary. CGI already implements a &radio_group subroutine that we can use and get rid of the loop altogether.

The end result is

use strict;
use CGI;

my $q = CGI::->new;

my @data = (
    [ Gender => [ 'Male', 'Female'] ],
    [ A => [ 'a', 'b', 'c'] ],
);

for (@data) {
    my ($column, $options) = @$_;

    print $q->radio_group(
        -name => $column,
        -values => $options,
        -default => '_',
    );

    # '_' is chosen as default as that will make
    # no value checked by default, as long as you
    # don't have '_' as an option.
}
[download]

If you at any time would like to do a lookup of which values that are accepted for a radio group you can degenerate your @data to %dataoptions by using

my %dataoptions = map @$_, @data;
[download]

Related documents:

• perlref	- Perl references and nested data structures
• perlfunc	- Perl builtin functions (look for map)
• CGI	- Simple Common Gateway Interface Class

ihb

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.