There is an important flaw in your test. The entire 100_000 character string is composed of the exact same characters. There ARE NO NULLS most of the time!

Try using this instead:

#!/usr/bin/perl

use 5.6.0;

use strict;
use warnings FATAL => 'all';

use Benchmark qw( cmpthese );

my $s1 = do_rand(0,100_000);
my $s2 = do_rand(1,100_000);

my $nulls = 0;
foreach my $idx ( 0 .. length($s1) ) { 
    if ( substr($s1,$idx,1) eq chr(0) ){
      $nulls++;
    } 
  } 

print "There are $nulls nulls in S1\n";
print "Sample data: [" . substr($s1,2,10) . "]\n";

cmpthese( -2, {
    'split1' => sub { my $s3 = split1( $s1, $s2 ) },
    'substr1' => sub { my $s3 = substr1( $s1, $s2 ) },
});

sub split1 {
  my ($s1, $s2) = @_;

  my @s1 = split //, $s1;
  my @s2 = split //, $s2;

  foreach my $idx ( 0 .. $#s1 ) { 
    if ( $s1[$idx] eq chr(0) ) { 
      $s1[$idx] = $s2[$idx];
    } 
  } 

  return join '', @s1;
}

sub substr1 {
  my ($s1, $s2) = @_;

  for my $idx ( 0 .. length($s1) ) {
    if ( substr($s1,$idx,1) eq chr(0) ) {
      substr($s1, $idx, 1) = substr($s2, $idx, 1);
    }
  } 

  return $s1;
}

# This makes sure that $s1 has chr(0)'s in it and $s2 does not.
sub do_rand {
    my $min = shift;
    my $len = shift;
    my $n = "";
    for (1 .. $len)
    {
        $n .= chr( rand(255-$min)+$min )
    }
  return $n;
}

__END__
[download]