I've already posted a node to CUFP about an MP3 shuffler. This is solving a different problem. The other week I've succeeded in getting audio working on one of my Linux boxes - one with a reasonable sound card. The issue is that my music collection is on a different machine.
Having rejected NFS and Samba shares as an option for getting at the mp3 files, I explore the various options for playing audio, and discover that Kaffeine can take a URL. Excellent! I tweak the server's Apache config, and can now serve music files to my Linux box, when I point a browser at the mp3. Pasting the URL into Kaffeine wasn't completely successful as it couldn't cope with URL escaping, so I needed to manually replace all the %20 with spaces.
Next, I'm thinking that what would be really nice is to prime Kaffeine with a playlist of random tracks from my music collection. Having dug around the file system, I couldn't find where the playlist is stored, but eventually, I realised this was the wrong approach, and discovered the "Save" and "Import" functions. What do they save playlists as? Answer: XML! Bingo! I can now write some Perl to automate the whole process: discover the albums and artists on my server, and make some random selections. Save the URLs, unescaped as an XML file and Bob's your old man's brother.
#!/usr/bin/perl
use strict;
use warnings;
use WWW::Mechanize;
use XML::Writer;
use IO::File;
use URI::Escape;
use Getopt::Long;
my $server = 'http://orinoco/musicfiles/';
my $ntracks = 10;
my $outfile = 'rand.kaffeine';
GetOptions(
'server=s' => \$server,
'tracks=i' => \$ntracks,
'output=s' => \$outfile,
);
my $mech = WWW::Mechanize->new;
$mech->get($server);
my @artists = $mech->find_all_links(text_regex => qr(/$));
my @pick;
for (1..$ntracks) {
my $rart = int(rand(@artists));
$mech->follow_link( text => $artists[$rart]->text );
my @albums = $mech->find_all_links(text_regex => qr(/$));
my $ralb = int(rand(@albums));
$mech->follow_link( text => $albums[$ralb]->text );
my @tracks = $mech->find_all_links(text_regex => qr(^\d\d));
my $rtk = int(rand(@tracks));
push @pick, $tracks[$rtk];
$mech->back;
$mech->back;
}
my $out = IO::File->new(">$outfile");
print $out "<!DOCTYPE XMLPlaylist>\n"; # Horrible hack: XML::Writer is
+ too strict
my $xml = XML::Writer->new( OUTPUT => $out );
#$xml->doctype('XMLPlaylist', undef, undef);
$xml->startTag( 'playlist', client => 'kaffeine');
for my $track (@pick) {
$xml->emptyTag( 'entry', url=>uri_unescape($track->url_abs));
}
$xml->endTag('playlist');
$xml->end;
Enjoy
-
Are you posting in the right place? Check out Where do I post X? to know for sure.
-
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big>
<blockquote> <br /> <dd>
<dl> <dt> <em> <font>
<h1> <h2> <h3> <h4>
<h5> <h6> <hr /> <i>
<li> <nbsp> <ol> <p>
<small> <strike> <strong>
<sub> <sup> <table>
<td> <th> <tr> <tt>
<u> <ul>
-
Snippets of code should be wrapped in
<code> tags not
<pre> tags. In fact, <pre>
tags should generally be avoided. If they must
be used, extreme care should be
taken to ensure that their contents do not
have long lines (<70 chars), in order to prevent
horizontal scrolling (and possible janitor
intervention).
-
Want more info? How to link
or How to display code and escape characters
are good places to start.