How to keep a script from bombing due to a missing module?

[yoda54]

Dear Monks,

I'm writing a general utility script with multi functions like the one below. My questions is when I run this on a system that is missing certian modules the script bombs. How can I avoid this behavior? I would like a script to continue doing whatever it can without it exiting. As always Thanks!!

#!/usr/bin/perl

use Getopt::Long;

GetOptions("tk" => \$tk);

if ($tk) { &tk(); }

do this
do whatever....
blah 
more blah 

sub tk {

        use Tk;
        use strict;
        more blah blah
        and yet more blah
}

Edited by Chady -- moved text outside of code tags.

[Nkuvu]

Read perldoc -f eval. But here's a sample:

#!/usr/bin/perl
use strict;

eval { require foo::bar }; 
# errors stored into $@
warn $@ if $@;

# also, you can set a flag to see if the module
# was available:
my $use_foo_bar = 1 unless $@;

print "I'm still going...\n";

if ($use_foo_bar)
{
    foo::bar::function();
}
else
{
    print "No foo for you\n";
}

[saintmike]

With eval and require you can check if a certain module is available or not. If it is, you can use it, if it isn't, you may decide on going an alternative path at runtime, like this:

eval { require SomeModule; };

if($@) {
    print "SomeModule not found, doing something else\n";
} else {
    SomeModule->do_something;
}

[eyepopslikeamosquito]

Good advice. Further, note that:

use SomeModule ();

is equivalent to:

require SomeModule;

while:

use SomeModule;

is equivalent to:

require SomeModule;
SomeModule->import();

with the use done at compile time and the require done at run time. See perlmod for more details.

For this to work smoothly with require, be sure to always call user-defined subroutines in SomeModule with parens, to allow the Perl parser at compile time to recognize subroutine calls in a module that has not been loaded yet.

See also: Re: New Discovery!!! (sub call without parentheses) - Coding Style and Re: How to create symlink using Perl? (Unix symlinks vs Windows Junctions).

[bobn]

To do a 'use', you must evall within quotes, as in:

#!/usr/bin/perl

BEGIN
{
    eval "use nosuchmodule;";

    if ($@)
    {
        print "'use' failed\n";
    }
    else
    {
        print "'use' ok\n";
    }
}