Re^2: When do filehandles close?

[gaal]

You don't even need IO::File:

    {
        open my $fh, $file or die "open: $!";
        $line = <$fh>;
    }
    # $fh is closed here

[beable]

Interesting... You made a little typo, that should be a semicolon on the end of the open() line. But look at this, it seems to solve pg's problem. And interestingly, IO::File has the same behaviour that pg is complaining about. Is this behaviour of $. a bug or a feature?

#!/usr/bin/perl

my $file = "pg-write3";

{
    open my $fh, $file or die "open: $!";
    $line = <$fh>;
    $line = <$fh>;
    print "two reads:\t$.\n";
}
# $fh is closed here
print "closed file:\t$.\n";

{
    open my $fh, $file or die "open: $!";
    print "open again:\t$.\n";
    $line = <$fh>;
    print "one read:\t$.\n";
}
# $fh is closed here
print "closed again:\t$.\n";

__END__

Output:
two reads:      2
closed file:    2
open again:     0
one read:       1
closed again:   1

[gaal]

(Thanks for the typo spotting; fixed.)

The $. behavior here is correct, if highly magical. Perl is keeping track of a property of an object that doesn't exist any more.

(Or, looking at it another way, it's not magical at all: $. is a global that gets set whenever a filehandle is accesed. Even if the handle is closed, the global remains. But there's still something DWIMmish going on, because each (active) filehandle does remember its own line number, so that when you access two files in alternation, $. knows how to keep track.

s/line number/record number/g for exactness.)