Modification of a read-only value

[Sprad]

I have a short function that takes a shell command, opens a pipe to it, and prints the output to both the screen and a log file (like tee). It works fine in most cases, but on occasion, I get the error "Modification of a read-only value attempted...".

Here's the code:

open(PIPE, "$CommandToExecute|");
while (<PIPE>) { # <--- This is the line that the error points to
    print LOG $_; 
    print $_; 
}

I'm not sure what might be causing this error when I'm just reading a pipe. Like I said, this doesn't happen every time, just occasionally. What can I look for?

[Aristotle]

I am guessing that this code is inside a subroutine and you're calling it while $_ is aliased to a constant. Try this:

for ( "read", "only", "value" ) {
    print "$_\n";
    $_ = "test"; # blows up
}

The problem is probably concealed in your code like so:

sub foo { $_ = "test"; }

foo(); # works

for ( "read", "only", "value" ) {
    print "$_\n";
    foo(); # blows up
}

The solution is to put a local $_; at some opportune point to decouple one piece of the code from the other. The trap is that aliasing constructs like for(), map and friends do not need such treatment, but while(<FH>) does.

[Sprad]

Yes! This was the problem. I'm not sure how far back I'm picking up constant values, but I changed the "while (<PIPE>)" to "while ($foo = <PIPE>)" and that took care of it. Thank you!

I didn't realize that whiles treated $_ differently. I'll watch that in the future...

[Aristotle]

:)

I first saw this in a question in the monastery a long time ago. That was a far nastier case, though: someone was getting spurious action at a distance. Turns out one of his map blocks was calling a sub containing a while(<FH>), and because map aliases $_, the function modified the values in his source array. Ouch.

Ever since, while(<FH>) used without a local has been a red flag in my mind. Always localize $_ when you use this construct. (Or use a different variable, as you did, of course.)

[ikegami]

while (<PIPE>)
is equivalent to
while (defined($_ = <PIPE>))
so you might want to use
while (defined($foo = <PIPE>))
instead of
while ($foo = <PIPE>)
What you are using will stop when you don't expect it (such as when you read in a blank line).

[tachyon]

I doubt that the error points to that line ( but as Aristotle points out I am wrong :-( ) Perl's error messages are on occasion out by a line or two. I highly recommend checking the return value of your opens ie:

open(PIPE, "$CommandToExecute|") or die "Can't get pipe open to $Comma
+ndToExecute: $!\n";

[Aristotle]

Sound advice, but unrelated to the problem. That omission would yield an intermittent readline() on closed filehandle, not the error the OP is seeing.

[tachyon]

I read your reply below. It is an error I have never encountered myself but it does look like the issue:

for ( qw( This is new to me ) ) {
    print "$_\n";
    open(PIPE, "dir|") or die $!;
    while (<PIPE>) { # <--- This is the line that the error points to
        print $_; 
    }
}
__DATA__
This
Modification of a read-only value attempted at script line 4.

Learn something every day. Thanks!

[ysth]

There are problems with localizing $_ if the current value is tied. You should use local *_ instead, at least until my $_ is available. Obviously within the scope of *_ you won't have access to @_, &_, or %_, so make sure you e.g. copy your subroutine parameters before the local. The special _ filehandle for filetests does still work after the local, though.