Re^4: Marilyn Vos Savant's Monty Hall problem

[TrekNoid]

I've never seen the Monty Hall problem presented with that stipulation explicit.

Here's the exact text of the original question, posed to Marilyn in her column in parade magazine:

Suppose you're on a game show, and you're given the choice of three doors. Behind one door is a car, behind the others, goats. You pick a door, say number 1, and the host, who knows what's behind the doors, opens another door, say number 3, which has a goat. He says to you, "Do you want to pick door number 2?" Is it to your advantage to switch your choice of doors?

http://www.fortunecity.com/victorian/vangogh/111/9.htm

The stipulation that the host knows what's behind the doors, and always opens a door with a goat is a given for this problem.

In fact, the additional information that it was 'Monty Hall' came later... which messed the whole thing up because they interviewed him, and he stated that he sometimes opened the prize door right away... and then everyone forgot the stipulations of the original question

I actually remember when this happened, because my college statistics professor was *consumed* with proving Marilyn wrong, and ended up conceding she was correct only after writing a program to do 10,000 permutations that bore her true

Trek

[tilly]

And that statement, while better than how it is presented the vast majority of the time, still isn't sufficient to make the answer unambiguous. There is still the question of Monty's motivations which could make it either adviseable to switch (up to 2/3 odds of winning) or to stay (up to 100% chance of winning).

An interesting follow-up on Marilyn. Later she tackled a restricted version of the problem that I presented at Spooky math problem (the restriction being that the two envelopes hold money, one has twice the money of the other) and correctly analyzed an argument for whether you should always switch. But she incorrectly analyzed whether you could do better than even odds. I know a couple of probability theorists who pointed out her mistake to her, but she never admitted to her mistake.

Make of that what you will.

[TrekNoid]

And that statement, while better than how it is presented the vast majority of the time, still isn't sufficient to make the answer unambiguous. There is still the question of Monty's motivations which could make it either adviseable to switch (up to 2/3 odds of winning) or to stay (up to 100% chance of winning).

I might be misunderstanding the issue then.

The question, as I understood it, is that I find myself on a game show, and I've picked a door... the host has just opened a door to reveal a goat, and then asked me if I want to change my choice to the other door.

So, in order to make my decision on this *one* event, I have to test it... and in order to test it, I must set up *identical* events, devoid of the host's motivation, to test whether I should change in this one instance.

It would be different if the question was 'in general, what should I do if I don't know the host's motivations', but the question states that the host opened a door with a goat... therefore my examination of the question should assume that fact

I don't know if this is coming across correct in text or not, so I apologize if it isn't...

Put another way, I'm setting up a model to that mimics the original question, which assumes the host opens a goat door

The possibility that the host *might* not offer the choice... or might reveal the prize first... etc... don't enter into the answering of this question, because the question supposes that the opening of the goat door has already happened, and now you have to make a decision based on the probabilities in play.

Trek

[tilly]

I believe that you are stating the problem correctly, but then adding a big assumption before analyzing it. You assume that that, whether or not you have the right choice, the host will always put you in the current situation - you've picked a door, and another has been opened showing a goat. With that assumption then you should switch, and will have 2/3 odds of winning if you do.

But that is a big assumption. In analyzing probabilities you cannot just work with what has happened, you have to work with what could have happened instead. A probability problem is never fully specified until it includes both knowledge of what did happen and what might have happened.

In particular in this case there are models of the host's possible behaviour in which you would be an idiot to switch. (The host is trying to keep you from winning the car.) There are models of the host's behaviour in which it is a good idea to switch. (The host wants to draw the game out.) And the problem statement does not provide enough information to unambiguously decide which model of the host's behaviour is correct. (Saying that the host has enough knowledge to always draw the game out is not saying that the host will choose to do that.)

Therefore the problem is not fully specified. To come up with an answer you have to add an assumption of some sort.

If you want to make it truly unambiguous, you can state the problem like this, Suppose you're on a game show, and you're given the choice of three doors. Behind one door is a car, behind the others, goats. The game works like this; you pick a door and the host, who knows what's behind the doors, will open another door and show you a goat. Then the host asks whether you want to switch your choice. You decide, then the host opens the other doors and you get the car if you've chosen it. When you play this game, is it to your advantage to switch your choice of doors?

The wording change is subtle but important. With this wording it is clear that, no matter what, the first time the host opens a door there will always be a goat. Not only have you been told what actually happened in the game, but you've also been told what would've happened no matter what your initial choice was.

[BrowserUk]

I'm not sure of the relevance of this. Stats was never my strong suit but...

If the following simulation bears any resemblance to reality (of the re-stated version of the problem), then you only get a greater chance of winning if you always switch your choice after the host opens the first door on the goat.

If at that time you make another choice--either, whether to switch or not, or a random choice between the two remaining doors (which amounts to the same thing?)--then your odds of success remain at 33.33%.

#! perl -slw
use strict;
use List::Util qw[ shuffle ];

our $TRIALS ||= 1_000_000;
my $DIVISOR = $TRIALS / 100;

my( $stick, $switch, $newChoice );

for my $try ( 1 .. $TRIALS ) {
      ## Randomly hide the prizes behind the doors.
    my @doors = shuffle 'car', 'goat', 'goat';

      ## Pick a door
    my $choice = int rand 3;

      ## The host opens a door that I didn't pick
      ## and that isn't the car
    my $opened = grep{ $_ != $choice and $doors[ $_ ] ne 'car' } 0 .. 
+2;
    
      ## Count my wins if I stick or switch
    $doors[ $choice ] eq 'car' ? $stick++ : $switch++;
    
        ## Make a new choice from the remaining two
    my $new = ( grep{ $_ != $opened } 0 .. 2 ) [ rand 2 ];

      ## And if I make a completely new random choice.
    $doors[ $new ] eq 'car' and $newChoice++;
}

printf "Odds of
    Choose again: %.3f
    Win if you don't switch: %.3f
    Win if you do switch: %.3f\n",
    $newChoice / $DIVISOR, $stick / $DIVISOR, $switch / $DIVISOR;

__END__
P:\test>test
Odds of
    Choose again: 33.331
    Win if you don't switch: 33.286
    Win if you do switch: 66.714

P:\test>test
Odds of
    Choose again: 33.370
    Win if you don't switch: 33.353
    Win if you do switch: 66.647

Assuming that this simulation isn't at fault, I'd love to see a (preferably layman's terms) explaination for why a predetermined strategy (always switch) would have such an effect on the odds of success?

[Solo]

Maybe it's easier to think about like this: if you always switch, you only lose if you picked the door with the car first. That's a 1 in 3 chance to lose. (And a 1 in 3 chance to win if you never switch).

[TrekNoid]

Assuming that this simulation isn't at fault, I'd love to see a (preferably layman's terms) explaination for why a predetermined strategy (always switch) would have such an effect on the odds of success?

Suppose there were 100 doors... and I allowed you to choose one of them, what's the odds you picked the right door? 1%

What's the odds that the prize is behind one of the other 99? 99%

So, if I gave you a choice of switching your choice from Door 1, and allowing you to pick all 99 of the other doors, which would you take? Obviously, the 99.

The torture is that I first open 98 of the goat doors (because I know where the prize is), leaving two... The one you picked, and the one remaining. None of that changes the fact that you're initial guess was only 1% chance of guessing right.

Therefore, switching from your initial choice at the last minute is effectively the same as changing to all 99 doors.

Occassionally this strategy would fail, but only about 1% of the time, since that was the likelihood you chose correctly to begin with.

Same is true with three doors. Your chance of picking correctly initially is 1/3rd... If you were allowed to switch to the other two doors, you'd have a 2/3rds chance of winning.

At least, that's how it was initially explained to me, and it seems pretty reasonable.

Trek

[tilly]

Your simulation is bad. $opened is always 1 or 2, depending on whether you picked a car. In fact $opened is (1/3 odds) the same as the door you pick. After that it is coincidence that you did a calculation that came out to the right answer.

Here is code that lets you try different scenarios and see how Monty's behaviour and knowledge affect the outcome. You can uncomment the scenario that you want to see that behaviour.

#! perl -slw
use strict;
use List::Util qw[ shuffle ];

my( $stick, $switch, $skip_goat, $skip_car ) = (0, 0, 0, 0);

for ( 1 .. 100_000 ) {
    ## Randomly hide the prizes behind the doors.
    my @doors = shuffle 'car', 'goat', 'goat';

      ## Pick a door
    my $choice = int rand 3;

    ####
    ## Uncomment the option you want here to see different scenarios.
    ###

    ## Option 1: The host opens a door that I didn't pick
    ## and that isn't the car
    #my @available = grep{ $_ != $choice and $doors[ $_ ] ne 'car' } 0
+ .. 2;

    ## Option 2: The host opens a random door
    #my @available = grep{ $_ != $choice } 0 .. 2;

    ## Option 3: The host tries to be malicious
    #my @available = grep{ $_ != $choice and $doors[ $_ ] eq 'car' } 0
+ .. 2;
    #@available = grep{ $_ != $choice } 0..2 if not @available;

    ####
    ## End of options
    ####

    # Monty chooses which door to open from the choices
    # that he might make.
    my $opened = $available[rand(@available)];

    if ($doors[$opened] eq 'car') {
        $doors[ $choice ] eq 'car' ? $skip_car++ : $skip_goat++;
        next;
    }

    ## Count my wins if I stick or switch
    $doors[ $choice ] eq 'car' ? $stick++ : $switch++;
}

printf "Odds of
    Not getting here if you were originally right: %.3f
    Not getting here if you were originally wrong: %.3f
    Win if you don't switch: %.3f
    Win if you do switch: %.3f\n",
    $skip_car / (( $stick + $switch + $skip_goat + $skip_car) / 100 ),
    $skip_goat / (( $stick + $switch + $skip_goat + $skip_car) / 100 )
+,
    $stick / (( $stick + $switch) / 100 ),
    $switch / (( $stick + $switch) / 100 )

Now that said, let me explain why the odds are what they are for each option.

In Option 1, you pick a door and have 1/3 odds of being right. There are 100% odds that you'll see a goat, so the fact that you saw one tells you nothing. Therefore your odds of being right remain 1/3. Since switching makes you right if you were wrong, your odds if you switch are 2/3 - so you want to switch.

In Option 2, you pick a door and have 1/3 initial odds of being right. However if you were right, then you're guaranteed to see a goat next, while if you're wrong, you have only even odds of seeing a goat next. Therefore the knowledge that you actually saw a goat conveys information - if you do the math just enough information to tell you that you now have even odds of being right.

In Option 3, you again pick a door and have 1/3 initial odds of being right. However the fact that you saw a goat gives you considerable information - it literally tells you that you must be right. Since you're right, you don't want to switch.