Read Last Line of A File Only

[Anonymous Monk]

I want to read the very last line of the file only.
How do I accomplish this in Perl??

[Aristotle]

open my $fh, "<", $filename
    or die "Can't open $filename: $!\n";

my $lastline;
$lastline = $_ while <FILE>;
print "$lastline\n";

Or

use Tie::File;
tie my @file, 'Tie::File', $filename
    or die "Can't open $filename: $!\n";
print @file[ -1 ];

Or

use File::ReadBackwards;
tie *FH, 'File::ReadBackwards',  $filename
    or die "Can't open $filename: $!\n";
my $lastline = <FH>;
print $lastline;

Or any of a myriad others.

Which one to pick depends on your precise circumstances.

[jbware]

I'm sure there are more posts, but doing a quick search on perlmonks, I found "Reading the last line of a file in a Pure Way.". This has some examples as well as links to other posts on the same topic.

- jbWare

janitored by ybiC: Changed [http://...] link to Monastery-style [id://...] link, to avoid logging out monks with cookie set to different perlmonks domain

[insensate]

perl -ne'print if eof' < my-reasonably-short-file

Has to read through the entire file... so I'm sure there are more efficient and practical solutions using modules etc...

[davido]

I like File::ReadBackwards' object oriented interface. ...and just for the fun of it, here's a somewhat golfy usage of that interface:

use File::ReadBackwards;
print +( 
         File::ReadBackwards->
         new( 't1000f.txt' ) || die $! 
       )->readline();

Of course, you'll need to alter the filename to whatever file it is that you're trying to read. On my system, t1000f.txt is a newline delimited text file listing the top 1000 most common English words in common speech, sorted in descending order by frequency of use. It turns out that 'neck' is #1000. :)

[Plankton]

Maybe you could use tail -1

#!/usr/bin/perl -w
 
use strict;
 
while( 1 ) {
        my $file = shift || last;
        open TAIL, "tail -1 $file|" or die "can't do tail -1 $file:$!\
+n";
        my $line = <TAIL>;
        print $line;
        close TAIL;
}

[Aristotle]

Or better yet, using the safer syntax options available in 5.6 and later:

my $lastline = do {
    open my $pipe, '-|', tail => -1, $file
        or die "Can't spawn tail: $!\n";
    <$pipe>;
};
print $lastline;

I'm not sure why you chose to write your loop that way, either. Why the obfuscatory infinite loop with an abort condition as in this?

while( 1 ) {
    my $file = shift || last;
    # ...
}

It took me a moment to realize that you meant something entirely different than what I assumed at first glance. The natural thing would have been to put the abort condition where you normally put it: in the loop condition.

while( @ARGV ) {
    my $file = shift;
    # ...
}

Of course, that's clearer written as

for my $file ( @ARGV ) {
    # ...
}

So we get

for my $file ( @ARGV ) {
    my $lastline = do {
        open my $pipe, '-|', tail => -1, $file
            or die "Can't spawn tail: $!\n";
        <$pipe>;
    };
    print $lastline;
}

I find that significantly clearer despite the changes not changing any of the semantics.

[bronto]

Or better yet, using the safer syntax options available in 5.6 and later:

my $lastline = do {
    open my $pipe, '-|', tail => -1, $file
        or die "Can't spawn tail: $!\n";
    <$pipe>;
};
print $lastline;

Interesting. Could you please point me to the documentation of this feature? I took a look around perldoc and couldn't find it, so I am surely searching the wrong way

Thanks in advance