filehandle question

[warpod]

What is wrong with this code?

==== test. pl ======
#!/usr/bin/perl
use strict;
use mmm;

local* F;
mmm::fopen(F, ">tst");
print F "hi";
mmm::fclose F;

==== mmm.pm ======
#!/usr/bin/perl
use strict;
package mmm;
BEGIN {}
sub fopen(*;$)
{
  local *FH = $_[0];
  return CORE::open(FH, $_[1]);
}
sub fclose(*)
{
  local *FH = $_[0];
  return CORE::close(FH);
}
END { }
1;

when executed it says:
print() on unopened filehandle F at test.pl line 7.
but if I move fopen and fclose into test.pl, then this code

local* F;
fopen(F, ">tst");
print F "hi";
fclose F;

works just fine. What is wrong in package?

[BrowserUk]

You can't pass a glob by bareword. Try this:

#!/usr/bin/perl
use strict;
use mmm;

local* F;
mmm::fopen( *F, ">tst");
print F "hi";
mmm::fclose *F;

[revdiablo]

It may be beside the point, but -- assuming you have a new enough perl -- I would recommend avoiding bareword filehandles, and switching to autovivifying lexicals:

  use strict;
  use warnings;

  {
    package mmm;
    sub fopen  { CORE::open  $_[0], $_[1]; }
    sub fclose { CORE::close $_[0];        }
  }

  mmm::fopen(my $fh, ">test");
  print $fh "Foo, bar.\n";
  mmm::fclose($fh);

[hv]

If you define fopen in the same package as you use it it works fine. When passing the bareword to the mmm package, however, it gets interpreted as *mmm::F instead of *main::F, so the file has been opened but in the wrong glob.

Given the prototype, this is arguably a bug - the bareword 'F' should be coerced to a glob in the caller's context. However there is no guarantee it is easily fixable - I suspect that it is currently passed as a simple string, and not turned into a glob reference until the actual assignment in mmm::fopen().

Hugo

[bobf]

As soon as I read your error message I thought, "how do you know you opened F in the first place?" Then I read the rest of your question and the other responses and realized that the globbing issue was the primary problem. Nonetheless, you should always check the return value of open to make sure it succeeded. If open fails, you will get the same error (print() on unopened filehandle F) when you try to print to the filehandle later.

open, perlopentut

HTH