Yet another POD to HTML converter

[Corion]

Category:

HTML Utility

Description:

Thilosophy was looking for a converter of pod to HTML. I uploaded mine, which mostly generates a local HTML tree with relative internal links.

Steal the corresponding css from http://www.corion.net/perl-dev/style.css.

#!/usr/bin/perl -w
use strict;
use Pod::Simple::HTML;
use File::Find::Rule;
use File::Spec;
use File::Basename;
use File::Path;

=head1 NAME

local-doc.pl - create local documentation

=cut

my ($docdir,$bindir) = @ARGV;
my $rel_docroot = '.';

{
  no warnings 'redefine';
  sub Pod::Simple::HTML::resolve_pod_page_link {
    my ($self,$link) = @_;
    my $to = $link;
    $to =~ s!::!-!g;
    $to .= '.html';
    # warn "$rel_docroot/$to";
    return "$rel_docroot/$to";
  };
};

my @files = File::Find::Rule->file()->name(qr(^.*\.(pm|pl|pod)$))->in(
+$bindir);

for my $file (@files) {
  my $input = $file;

  my @outfile = File::Spec->splitdir( File::Spec->abs2rel( $file, $bin
+dir ));
  my $outfile = File::Spec->catfile( $docdir, join "-", @outfile );
  $outfile =~ s/\.[^.]+$/.html/;
  # print "Generating $outfile";

  my $stylesheet = "style.css";

  my $parser = Pod::Simple::HTML->new();
  my $html;
  $parser->output_string($html);
  $parser->parse_file($file);
  $html =~ s!</title>\s*</head>!</title><link rel="stylesheet" href="$
+stylesheet" /></head>!sm;

  open OUTPUT, ">", $outfile
    or die "Couldn't create '$outfile': $!";
  print OUTPUT $html;
  close OUTPUT;

  # print ", done.\n";
};

=head1 AUTHOR

Max Maischein ([e-mail])

=cut

[dpavlin]

Thanks for nice script. I had to change regex which adds stylesheet to:

$html =~ s!</head>!<link rel="stylesheet" href="$stylesheet" /></head>
+!sm;

I think that this change show make it more compatibile with various html formats that Pod::Simple::HTML produce (I might have different version than you).

[jmcnamara]

With 3.xx versions of Pod::Simple and Pod::Simple::HTML you can specify the CSS source using the html_css() method:

  ...
  $parser->output_string($html);
  $parser->html_css(qq(<link rel="stylesheet" href="$stylesheet"/>));
  $parser->parse_file($file);
  ...

That way you don't have to do the s///.

An alternative approach to the general problem would be to use Pod::Webserver.

--
John.