subroutines and arguments

[natty_dread]

I know there's a similar question out there, but it didn't help me. I'm trying to read a server list and perform actions on each server one at a time. However, I cannot access the variable. Here's some code:

open (SERVERLST, "< svr_daily.csv");

foreach my $svr (<SERVERLST>)
{
        chomp $svr;
       &ls_engine;
}

sub ls_engine {
        my $ls_eng = $_[0];
        system ("wdmlseng -e $ls_eng");
        }

My problem line of code is passing the global var $svr into the sub. I've tried my $ls_eng = shift (@_) AND my $ls_eng = $_; also.........I'm sure it's something small.

[phaylon]

"I cannot access the variable" is a very very unfortunate description of what you want to do.

$svr is declared with "my", so it's lexical. Here, you will only find it in your for-loop. Try:

for my $svr (<SERVERLST>) {
   chomp $svr;
   ls_engine ($svr);
}

And read up in 'perldoc perlsub' about what & actually does.

[Fletch]

And not directly related to your problem, but ALWAYS CHECK THE RETURN VALUE FROM open!

open( SERVERLST, "<", "svr_daily.csv" ) or die "Can't open server dail
+y CSV: $!\n";

[jhourcle]

And while you're at it, don't pass a single argument to system, either. Especially if you're passing in stuff from a file. (I'd recommend checking the lines from the file, even with the following changes):

open (SERVERLST, '<', 'svr_daily.csv')
    or die "Can't read from server daily CSV: $!";

foreach my $svr (<SERVERLST>) {
    chomp $svr;
    ls_engine($svr);
}

sub ls_engine {
    my $ls_eng = shift;
    system qw(wdmlseng -e), $ls_eng;
}

Update: per Fletch, fixed the mistake w/ qw(). Had previously been:

system qw(wdmlseng -e $ls_eng);

[Fletch]

perl -le 'print for qw( $erm $do $you $really $want $qw? )'

Remember qw() is a compile time construct. But yes, if you're not sure about the pedigree of the contents of the file you don't want to pass a single scalar to system.

Update: Not to mention that qw() is equivalent to split(' ', q/STRING/) to begin with and hence wouldn't do any interpolation.

[deibyz]

Have a look at perldoc perlsub.
You're not passing any parameter to your subroutine, try something like:


foreach my $svr (<SERVERLST>)
{
        chomp $svr;
        ls_engine($svr);
}

Hope it helps,
deibyz

[maa]

why not try: ls_engine($svr); instead?