Re^2: Regular Expression Doubt

[reasonablekeith]

You seem to be arbitrarily splitting on spaces. This will break unless there's a clear space either side of the +. A better option would be as follows.

my $text = '1&plus;2<maths> &plus; dfdf</maths>';

my $output = "";
while ($text =~ m/((<maths>.*?<\/maths>)|([^<]*))/gs) {
    if ($2) {
        $output .= $2;
    } else {
        my $segment = $3;
        $segment =~ s/&plus;/&thinsp;&plus;&thinsp;/g;
        $output .= $segment;
    }
}
print $output . "\n";

The basic premise being to scoop up and ignore (push onto output) anything in <maths>, or scope up as much that can easily be determined not to be in <maths> (ie no angle brackets) and parse that before putting it on the output.

[Anonymous Monk]

my $text = '1 &plus; 2 <br> <maths> &plus; dfdf</maths>';

my $output = "";
while ($text =~ m/((<maths>.*?<\/maths>)|([^<]*))/gs) {
    if ($2) {
        $output .= $2;
    } else {
        my $segment = $3;
        $segment =~ s/&plus;/&thinsp;&plus;&thinsp;/g;
        $output .= $segment;
    }
}
print $output . "\n";

__END__
1 &thinsp;&plus;&thinsp; 2 br> <maths> &plus; dfdf</maths>

You lost a < here.

[reasonablekeith]

dammit

my $output = "";
while ($text =~ m/((<maths>.*?<\/maths>)|&plus;|.)/gs) {
    if ($2) {
        $output .= $1;
    } else {
        my $segment = $1;
        $segment =~ s/&plus;/&thinsp;&plus;&thinsp;/g;
        $output .= $segment;
    }
}
print $output . "\n";

[Anonymous Monk]

Eh, if you go that way, it could be made much more efficient. No need for the s/// - you're matching any &plus; already:

my $output = "";
while ($text =~ m{\G(?:&plus;|(<maths>.*?<\/maths>|[^&<]+|.))}gs) {
    $output .= $1 || "&thinsp;&plus;&thinsp;";
}
print $output, "\n";

[sh1tn]

# in rare cases with no spaces:
...
$text =~ s/(?!\s)(<maths>)/ $1/g;
...