Generating standard length strings

[kage-yojimbo]

I have written this very primitive subroutine that pads a string with blanks to return a standard length string. I'm sure there is a much easier way to do this job - any suggestions?
Thanks!

sub standard_fill

{
my $string = $_[0];
my $length = $_[1];

for (my $i = length($string); $i <= $length; $i++) {
$string = $string." ";
}

return $string;
}

[Roy Johnson]

sprintf "%-${length}s", $string" Update: note that length here is the name of a variable, not the function call being interpreted as a reference.

[ihb]

sprintf '%-*s', $length, $string

Less noise in the format.

ihb

[Corion]

As nobody has mentioned it already, there is another way:

sub rpad { pack "A$_[1]", $_[0]};

[crashtest]

Note that your sub will cut off the input string if its length is larger than the padding width:

sub rpad { pack "A$_[1]", $_[0] };
my $string = 'averylongstringthatislongerthan10charsforsure!';

print "]", rpad($string, 10), "[\n";

__END__
]averylongs[

I am not sure if that is what the OP intended.

[BrowserUk]

sub standard_fill{ return substr $_[ 0 ] . ' ' x 100, 0, $_[ 1 ] }

[jdporter]

sub standard_fill
{
  my( $string, $length ) = @_;
  sprintf "%-${length}s", $string
}

[crashtest]

And just for variety (TIMTOWTDI, after all), I first thought of using pack:

sub pad{
   my ($string, $length) = @_;
   return (length($string) < $length ? pack("A$length", $string) : $st
+ring);
}

... although after reading all the responses, I agree that sprintf is the best way to go.

[RazorbladeBidet]

You want string multiplication a la:

 sub standard_fill {
   my $string = $_[0];
   my $length = $_[1];
   
   my $orig_string_length = length($string);

   $string .= " " x ($length - $orig_string_length);
   
   return $string
 }

(code untested)

I'll leave the golfing to the PGA tour ;)

[Fletch]

my $str = sprintf( "%${len}s", $str );

perldoc -f sprintf if you need to do anything fancier like left justify.

Update: D'oh, the original question was about left justified. Not like there's not 15 bazillion other answers to pick from . . . :)