split an array in two

[water]

This code splits an array in two. It seems ugly and long. Is there a better perl way? Not looking for golf, just looking to learn better idioms. Thanks!

sub split_array_in_two {
    my (@x) = @_;
    return ([],[]) unless @x;
    my $n = (scalar @x) -1;
    my $m = int ($n/2);
    return ( [ @x[0 .. $m]], [ @x[($m+1) .. $n]]);
}

[Zaxo]

Splice:

sub split_array_in_two {
    my @x = @_;
    my @second = splice @x, @x/2;
    \@x, \@second;
}

Explicitly returning empty array references is unnecessary, since an empty argument list will give you that anyway.

[Roy Johnson]

Note that your solution divides the data differently than the OP's code. Use 1+$#x/2 instead of @x/2 to get the OP's result.

You can also write it

sub split_array_in_two{ \@_, [splice @_, 1+$#_/2] }

[Tommy]

sub split_array_in_two {return unless @_;[splice(@_,0,(int scalar(@_)/
+2))],\@_}

[mda2]

This is my code. Less var changes, more eficient (?)...


sub split_array_in_two {
 my $len = int($#_/2); 
  return unless ( @_ );
 return [ @x[0..$len] ], [ @x[$len+1..$#x] ]; 
}

scalar(@_) is numbered from 1 to elements... and
$#_ is numbered from 0 to limit.

Your code isnīt long... is readable and suficient.

[salva]

scalar(@_) is numbered from 1 to elements... and $#_ is numbered from 0 to limit.

What do you mean? when @x is empty scalar(@x) is 0 and $#x is -1.

[salva]

sub split_array_in_two { ([splice @_, @_/2], \@_)[1,0] }

or

sub split_array_in_two { my $l=@_/2; [@_[0..$l-1]], [@_[$l..$#_]] }

or the funny recursive way:

sub da (\@\@\@) {
  my ($s, $a, $b)=@_;
  push(@$a, shift @$s), da(@$s, @$b, @$a) if @$s
}

my (@a, @b);
my @s=1..7;
da(@s, @a, @b);
print "@a - @b\n"

[Roy Johnson]

You don't need to copy the array; creating an arrayref does that. And you can calculate the indices on the fly, so you need no temp variables or calls to splice. Just one expression:

sub split_array_in_two {
    ([@_[0..$#_/2]], [@_[$#_/2+1..$#_]]);
}

for (0..5) {
  print map("<@$_>", split_array_in_two(1..$_)), "\n";
}

[Anonymous Monk]

sub split_array_in_two{ [@_[0..@_/2-1]], [@_[@_/2..@_]] }

[Roy Johnson]

You're reaching beyond the end of the array, resulting in an extra undef getting stuck on the end of your second arrayref. Also, a one element list gets replicated in both resulting arrays.