split with separators but dont include in the array

[anniyan]

I have a string like

$str = '<chap&&<book||<table&&<list';

I want to split that with && and || but i dont want to include those && and || in the array.

If i use the following code, it splits correctly but it stores the && and || in the array.

@arr = split /(?=(&&|\|\|))/, $str;

How to do this?

[ikegami]

We start with:

@arr = split /(?=(&&|\|\|))/, $str;
# @arr = ('<chap', '&&', '&&<book', '||', '||<table', '&&', '&&<list')
+;

Use non-capturing (?:...) instead of the capturing (...):

@arr = split /(?=(?:&&|\|\|))/, $str;
# @arr = ('<chap', '&&<book', '||<table', '&&<list');

But neither are needed here

@arr = split /(?=&&|\|\|)/, $str;
# @arr = ('<chap', '&&<book', '||<table', '&&<list');

Are you sure you want to use (?=...)?

@arr = split /&&|\|\|/, $str;
# @arr = ('<chap', '<book', '<table', '<list');

[Roy Johnson]

You're using lookahead and capturing parentheses. You want an unparenthesized expression so the separators are discarded.

@arr = split /&&|\|\|/, $str;

[anniyan]

Roy Johnson and ikegami thanks for your quick replies. Here i have one question. First i tried like the following.

@arr = split /(&&|\|\|)/, $str;

But it included && and || in the array. Then only i went for lookahead option.

But as per yours reply it works fine if i remove that extra grouping.

@arr = split /&&|\|\|/, $str;

Why is it so? Could you please explain. Then if there is many separators how to with that?

[Roy Johnson]

Anything in capturing (plain) parentheses will be returned as a separate item in the split results. If you need parentheses for grouping, use non-capturing parentheses, which open with (?: instead of just (.

No matter how many alternative separators you have, you don't need parentheses at all unless the alternatives are only part of the separator and you need to "factor out" common substrings. For example, if your valid separators were "foo&&", "foo||", and "++", you could split on

/foo(?:&&|\|\|)|++/

[McDarren]

@arr = split /(&&|\|\|)/, $str;

But it included && and || in the array.

That's because you used capturing parentheses.

Then if there is many separators how to with that?

You use the pipe "|" character to separate multiple options, like so:

@arr = split /foo|bar|meh/, $str;

That would split the string on any occurrences of "foo", "bar" or "meh" without including them in the resultant list.
This may not be clear in your original example, as one of the strings you are splitting on is a double-pipe "||", so the escaping of those adds a bit of "noise" to the split expression :)

[polettix]

The manual (split in this case) can usually dissipate such doubts:

               If the PATTERN contains parentheses, additional
               list elements are created from each matching sub-
               string in the delimiter.
                                                                      
+          
                   split(/([,-])/, "1-10,20", 3);
                                                                      
+          
               produces the list value
                                                                      
+          
                   (1, '-', 10, ',', 20)

[Limbic~Region]

anniyan,
Sometimes it is important to start out with functional code and then work on improving it to be "right". Have you considered making it two steps?

my @matches = grep { $_ !~ /(\&\&|\|\|)/ } split /(\&\&|\|\|)/, $str;

This obviously isn't the way you want to leave the final code but it is better to having something that works that you are unhappy with then something that doesn't work at all. You can always improve. Commentary after the code snippet added

[anniyan]

Thanks, Yes it works fine, is it not possible to write with lookahead and look behind?