problems splitting string

[Anonymous Monk]

Hi all, I am having problems spliting the below:

$string = '1 Cat 2 Dogs 3 Hamsters';

I want to split the string, so that i have 1 Cat, 2 Dogs, 3 hamsters pushed onto an array? Thanks

[VSarkiss]

You want to split on a space only if followed by a digit, correct? This will do the trick:

@res = split /\s(?=\d)/, $string;

If there can be more than one digit, change that to:

@res = split /\s(?=\d+)/, $string;

You can find more on zero-width assertions in perlre.

[Anonymous Monk]

thanks for the help

[merlyn]

As illustrated by some of the answers, you can see that this is where "split" is probably the wrong tool.
• When it's easier to talk about what to throw away, use split.
• When it's easier to talk about what to keep, use a match-global.
Don't reach for the wrong tool. In this case, it was easier to talk about what to keep.

[Tanktalus]

For the split bullet, I would actually describe it as "When it's easier to talk about separators" - such as "I want to split on commas" or "I want to separate on colons" or "I want to separate right before each number (not necessarily each digit)".

If this is how you're thinking of the problem, then split is probably the right tool. However, given the original question, I get the feeling that the problem was being thought of as "what to keep" where using match-global is more in line with the real problem. The OP seems to be asking "How do I do X with Y?" - wanting to match stuff with split.

If you take away the context of the question, and it were to become "How do I get this string '1 Cat 2 Dogs 3 Hamsters' to become this list ('1 Cat', '2 Dogs', '3 Hamsters')", then I would think either split or match-global would be perfectly legitimate responses.

[mrborisguy]

What I was thinking would be to have a look ahead for a number.

my $string = '1 Cat 2 Dogs 3 Hamsters';
my @animals = split /(?=\d)/, $string;

    -Bryan

[VSarkiss]

That kinda works: it leaves a trailing space on the middle elements (i.e., '1 Cat ' instead of '1 Cat').

Of course, that may be immaterial to the OP -- can't tell.

[mrborisguy]

Yep. Good catch, I noticed that, and was changing it, then I noticed you posted. I tried to update with a solution using map to take off the trailing space, but it seems VSarkiss' solution is similar to mine but more elegant, so just refer down a few posts.

    -Bryan

[Hue-Bond]

This will do the trick:

my $string = '1 Cat 2 Dogs 3 Hamsters';
my @a = $string =~ m/\b\d+\s+\w+\b/g;
use Data::Dumper; print Dumper \@a;
__END__
$VAR1 = [
          '1 Cat',
          '2 Dogs',
          '3 Hamsters'
        ];

Update: if you want to push, try this:

my $string = '1 Cat 2 Dogs 3 Hamsters';
my @a;
push @a, $1 while $string =~ m/(\b\d+\s+\w+\b)/g;
use Data::Dumper; print Dumper \@a;
__END__
$VAR1 = [
          '1 Cat',
          '2 Dogs',
          '3 Hamsters'
        ];

[ikegami]

The trailling \b is useless, and your your code won't process "5 Golden Rings 4 Calling Birds"

[Anonymous Monk]

Why not? It won't be sorted in the way you assume would be required, but were never explicitly requested.