help needed in wantarray

[uva]

how the execution of the program decides wantarray function returns true or false.i tried in the coding but it always returned ture .i read the documentation also, in that they said about the context,i could not understand.can you please give example(code) which explains that.

[xdg]

The "context" means the context that the function is called in -- whether the values of the function will be used in list or scalar context.

use strict;
use warnings;

sub what_do_you_want {
    print wantarray ? "list\n" : "scalar\n";
}

my @list = what_do_you_want();   # prints "list"
my $scalar = what_do_you_want()  # prints "scalar"

[dorward]

use strict;
use warnings;
sub foo { 
        if (wantarray()) {
                print "Want!\n";
        } else {
                print "Don't want!\n";
        }
}
my $bar = foo();
my @baz = foo();

[brian_d_foy]

Actually, wantarray has three distinct return values: true, false but defined, and undef. These correspond to list context, scalar context, and void context.

sub fred { 
    ...
    unless( defined wantarray ) { ...void context }
    elsif( wantarray )          { ...list context }
    else                        { ...scalar context }
    }

You then ensure you're calling fred in the right context.

fred();               # void
my $fred    = fred(); # scalar
my( $fred ) = fred(); # list (because of the parens)
my @fred    = fred;   # list
print fred();         # list, print is a list operator
print scalar fred();  # scalar

For instance, you might look at Hook::LexWrap (or my TPJ article on it: "Wrapping Subroutines to Trace Code Execution".