removing arbitrary elements from an array?

[Anonymous Monk]

I'm writing a program to simulate the shuffling of a deck of cards. So far it works fine, with one problem -- repeat cards keep turning up. Is there any way to cut an arbitrary value out of an array? The code works like this:

while ($game_hand < 12) {
$_ = int rand(@deck);
push @hand, $_;
$game_hand++;
}

I'd like a function that could cut whatever value $_ gets out of @deck completely, during the loop so I don't have to go through and check it for redundancy at a later point (and yes, I know about splice: for whatever reason, in this case it doesn't work and ends up giving me more repeat values... ugh).

[chromatic]

The perlfaq suggests a Fisher-Yates shuffle:

sub fisher_yates_shuffle {
    my $array = shift;
    my $i;
    for ($i = @$array; --$i; ) {
        my $j = int rand ($i+1);
        next if $i == $j;
        @$array[$i,$j] = @$array[$j,$i];
    }
}

fisher_yates_shuffle( \@array );

This, walks backwards through the array (thus avoiding the repetition problem), swapping cards randomly. I would call this on your deck and then, depending on your card game, treat @deck as a queue.

[gronkulator]

ugly hack - pruning an array by value by checking each element sequentially

@deck=(0 ... 51);
$card=32;

prune_deck($card, \@deck);

print join("\n",@deck);

sub prune_deck (
    my $dupe = shift; # we assign $dupe to the id of the card we just 
+pulled
    my $deckref = shift;
    my @remainder; # a scratch array to hold what's left

    for my $card (@{$deckref}) {
        $card eq $dupe ? next : push(@remainder, $card); # save curren
+t card if not the one we pulled
    }

    @{$deckref}=(undef); # empty the deck
    push @{$deckref}, @remainder; # push back the remainder
    1;
}

[btrott]

As chromatic wrote, you should use the Fisher-Yates shuffle.

However, you said splice wouldn't work for you--I'm curious as to why. What was your code, using splice? I tried this:

while ($game_hand < 12) {
    push @hand, splice @deck, rand @deck, 1;
    $game_hand++;
}

and it worked for me.

This is, in fact, the very same algorithm that perlfaq4 warns against using.

So use the Fisher-Yates shuffle to shuffle your array.

[Anonymous Monk]

This doesn't exacty answer you question, but arrays are designed so that it is easy to pop and push elements onto and off of the top of the deck. Why not shuffle the deck first, and deal off the top?

[Anonymous Monk]

for a card game I'd build off of the Games::Cards module on CPAN as it already has tons of card-type logic built into it (includding shuffling). If all you want is shuffling of a list take a look at the Algorithm::Numerical::Shuffle module.