Re^2: create new task from main program

[benlaw]

Hi ,
I try to combined the code with threads,

but it shows "thread failed to start: Not a CODE reference at D:/Perl/lib/threads.pm" is that any go worse?

use strict;
use Win32::ChangeNotify;
use Win32::IPC;
use File::Basename;
use File::Glob;
use DBI;
use threads;

my $path = 'c:\temp\buffer\event';
#$|=1;
my @threads;

### Main program part

my $notify = Win32::ChangeNotify->new( $path, 0, 'FILE_NAME' );
my %last;@last{ glob $path . '\*' } = ();


CHECK_MAIN();


while( 1 ) {
        $notify->wait;

    $notify->reset;

    my @files = glob $path . '\*';

     if(@files == scalar keys %last) {
            my %temp;
            @temp{ @files } = ();
            delete @temp{ keys %last };
    
        foreach my $file (keys %temp){
            my $currentFile = basename $file;
            if ($currentFile =~ /\.log$/){
push @threads, async \&READ_FILE($file);
#                READ_FILE("$file");
            }
    
        }
    }

    undef %last;
    @last{ @files } = ();
}

$_->join for @threads;
exit 0;
 

sub CHECK_MAIN{
    

}

sub READ_FILE{

    my $file = shift;

    my $pattern;
    my $errMsg;

        open(F, "unix.txt")|| die "unix\.txt not found\nopen : $!";
    while(<F>){
        chomp($_);
        $pattern .= $_."|";
    }
    close(F);
    chop($pattern);

    my (@errlog, @normal) = ();
    chomp($file);
    $file =~ s/\\/\//g;
    sleep 1;


    open(TARGET, $file) || die "$file not found\nopen : $!";
    while (<TARGET>){
        if(/$pattern/ig){
            next if(/root\-oracle/ig);
            chomp($_);
            my $temp = "$&\|".$_;
            push (@errlog, $temp);
        }else{
            push (@normal, $_);
        }

    }
    close(TARGET) || warn "close : $!";

#    print "@errlog";
    #SEND_SMS(\@errlog) if(@errlog > 0);
    #ADD_DATA(\@errlog) if(@errlog > 0);

} # END of READ_FILE

[BrowserUk]

Changing

push @threads, async \&READ_FILE($file);

to

push @threads, async \&READ_FILE, $file;

should cure that problem.

Ie. You need to pass the address of the subroutine, and the parameter as separate items. What you were doing is calling the function and then passing the address of the return value to async

HTH.

[benlaw]

Thanks a lot ^^, moreover, thanks for your win32::changenotify 's code (http://perlmonks.org/?node_id=306191), it's a very good reference for the module!

[benlaw]

Ooop , 1 more problem ,
I found the program memory grows larger and not free up, i try to use threads->detach() but it seems cannot detach from memory

[BrowserUk]

Okay. Over the course of spawning 1000 threads, this version will use `1/16th (~13MB) of the memory required by my original version above. It substitutes a shared variable for the array of thread handles, and detaches the threads so they clean themselves up rather than sitting around consuming memory (~208MB) as in the original version.

The numbers will vary depending upon how many threads exist concurrently. If you are likely to be spawning anything like this number of threads, moving to a thread pool would be your best bet, though it is slightly more complex.

Without knowing what your program is actually doing, and it dynamic resource demands, it is quite likely that this version will also not be best for your application. Hence my /msg for further information. There is no one-size-fits-all solution.

#! perl -slw
use strict;
use threads;
use threads::shared;

$|=1;
our $N ||= 1_000;

my $threads :shared = 0;

for my $i ( 1 .. $N ) {
    ## if the condition is true
    if( $i & 1 ) { ## every odd number matches
        ## Start a thread to run the sub
        ## Passing the number as an argument
        ## And saving the thread object,
        async( \&other, $i )->detach;
    }
}

## Wait for all the threads to finish
sleep 1 while $threads;

printf "Check Memory"; <STDIN>;

## Done.
exit;

sub other{
    { lock $threads; ++$threads; }
    my( $number ) = @_;
    print "Other( $number ) starting";
    ## pretend we've doing something that takes a while...
    for( 1 .. rand 100 ) {
        print "Other( $number ) busy ...";
        Win32::Sleep 100;
    }
    print "Other( $number ) finished";
    { lock $threads; --$threads; }
}