my @TIMERS = qw[ 4 7 ];
my $TARGET = shift || 5;

my ($gcd, @c) = bezout(@TIMERS);
die "$TARGET is not egg-timer-able!" if $TARGET % $gcd;

my $iter = $TARGET / $gcd;
my @pos = grep { $c[$_] > 0 } 0 .. $#c;
my @neg = grep { $c[$_] < 0 } 0 .. $#c;
@c = map abs, @c;

printf qq[
Perform steps 1 & 2 in parallel:

Step 1: One after the other, start the following timers:
%s

Step 2: One after the other, start the following timers:
%s

Step 2 will finish exactly $gcd minutes before step 2, so when it
finishes, set aside the remaining $gcd minutes on the last timer.
],
join("\n", map "  $c[$_] of the $TIMERS[$_]-minute timers", @pos),
join("\n", map "  $c[$_] of the $TIMERS[$_]-minute timers", @neg);

print "\nRepeat the whole thing $iter times to $TARGET minutes set aside.\n"
   if $iter > 1;

sub bezout {
    if ( @_ > 2 ) {
        my ($g1, @c1) = bezout( @_[0,1] );
        my ($g2, @c2) = bezout( $g1, @_[2..$#_] );

        return ( $g2, (map { $c2[0]*$_ } @c1), @c2[1 .. $#c2] );
    }

    my ($x, $y) = @_;
    return ($y,0,1) if $x % $y == 0;

    my ($g, $s, $t) = bezout( $y, $x % $y );
    return ($g, $t, $s - $t * int($x/$y));
}