FORMAT Trouble

[SolidState]

Hi, Can anyone tell me if it is possible to define 2 different formats for the same filehandle?

The reason I am asking is that I want to print 2 different tables to the same text file and I don't want to use printf statements. For me at least, code that uses printf to print something as complex as a text table is hard to both write and read, hard to understand and hard to debug. It's also ugly, to boot :)

My current workaround is to close the file, reopen in append mode with a different filehandle name and define the second format with this name. Ugly, but works. Any other/better solutions?

Thanks in advance,
SolidState

[bobf]

It's a big ugly, but you can use select and $~ to change the format for a given filehandle. See perlform for more info. In the meantime, here is a brief example:

use strict;
use warnings;

open( my $outfh, '>', 'temp.txt' ) or die $!;

my ( $var1, $var2 ) = ( 'one', 'two' );

my $oldfilehandle = select $outfh;
$~ = "FORMAT1";
select $oldfilehandle;
write $outfh;

$oldfilehandle = select $outfh;
$~ = "FORMAT2";
select $oldfilehandle;
write $outfh;

$oldfilehandle = select $outfh;
$~ = "FORMAT1";
select $oldfilehandle;
write $outfh;


format FORMAT1 =
    @<<<<<   @<<<<<
    $var1,   $var2
.

format FORMAT2 =
    @<<<<<XXX@<<<<<
    $var2,   $var1
.

close $outfh;

And the output file:

    one      two
    two   XXXone
    one      two

[SolidState]

This is exactly what I wanted! I read perlform, but didn't understand it. Your example it so much clearer!

Thanks!

[shmem]

First thing to do, read perlform and perlvar :-)

Just select the format you like assigning to $~. Example:

#!/usr/bin/perl

our(@l,$c);
while(@l = getpwent) {
    $~ = $c++ % 2 ? 'foo' : 'bar';
    write;
}

format foo =
left @<<<<<<<<<<<< @<<<<<<<<<<<<
$l[0],$l[7]
.
format bar =
right @>>>>>>>>>>> @>>>>>>>>>>>>
$l[0],$l[7]
.

[diotalevi]

I kind of doubt you can do what you asked for. The replacement for that in perl 6 is also available in perl 5 with Perl6::Form.