parsing output of UNIX `who` command

[chinamox]

Greetings again all of you good monks.

I am attempting to set up a very simple Perl app using the 'who' command in Unix.

Basically I want to set up a simple hash using somthing like:

my %who=('who -q');

I would then like then like to set each of the returned usernames as keys for the hash and have the values in the hash show the number of sessions that a user is logged in.

The read out would look something like:

Beckysue is logged in 1 time.
Billybob is logged in 3 times.
BubbaJoe is logged in 2 times. 
Saranne  is logged in 1 time. 
<br><br>
ect...

I have a strong urge to try the functions keys(%hash) and values(%hash) but I think I also might be haveing problems passing data from that 'who' command.



Thank you in advanced, I am trying to learn Perl from my home in Beijing with very limited help in meatspace. I have been ramming my head into the desks for the last few hours and the this is upseting the little old lady nextdoor. If anyone can offer a hint, you would be my hero for the day (or night).

2006-10-02 Retitled by planetscape, as per Monastery guidelines

( keep:0 edit:7 reap:0 )

Original title: 'Perl in Unix question'

[gellyfish]

As an alternative to parsing the output of the external command you might consider using Sys::Utmp:

use Sys::Utmp;
                                                                      
+          
my $utmp = Sys::Utmp->new();
                                                                      
+          
my %users;
                                                                      
+          
while ( my $utent =  $utmp->getutent() )
{
   if ( $utent->user_process )
   {
      $users{$utent->ut_user}++;
   }
}
                                                                      
+          
$utmp->endutent;
                                                                      
+          
foreach my $user (keys %users)
{
   printf "%s is logged in %d times\n", $user, $users{$user};
}

/J\

[chinamox]

You are a saint among monks. Thank you.

[shmem]

You could read the output of who via backticks as one long string with embedded newlines:

my $str = `who`;

To get a hash of it, you'd have to split the string on newlines, then split each line:

foreach my $line (split /\n/,$str) {
    my ($user, $remainder) = split /\s/,$_,2;
    $hash{$user}++;  # just increment the value
}

But you could also use open to read from who:

open(PIPE,"who |") or die "Can't run 'who': $!\n";
while(<PIPE>) {
    my ($user, $remainder) = split;  # implicit split splits $_ on /\s
++/
    $hash{$user}++;

Now you have a populated hash.

# sort by user
foreach my $user(sort keys %hash) {
    print "$user logged in $hash{$user} times.\n";
}
# sort by times users are logged in
foreach my $user(sort {$hash{$a} <=> $hash{$b}} keys %hash) {
    print "$user logged in $hash{$user} times.\n";
}

--shmem

[spadacciniweb]

Try:

#!/usr/bin/perl

use warnings;
use strict;

my $who = `who -q`;

if ($who =~ /(.+)\n# users/) {
    $who = $1;
}

my @who = split / /,$who;

my %who;
foreach $_ (@who) {
    $who{$_}++;
}

foreach $_ (keys(%who)) {
    print $_, ' is logged ', $who{$_}, " times\n";
}

[Anonymous Monk]

Given that backticks in list context return a list of lines, and each line starts with the username (which you want to use as a key), I'd do something like:

my %who;
foreach my $user (`who`) {
    $user =~ /^(\S+)/ or next;
    $who{$1}++;
}
while (my($user, $count) = each(%who)) {
    print "$user is logged in $count time";
    print $count == 1 ? ".\n" : "s.\n";
}

who -q just gives the total number of users logged in on my system, so that's not very useful for counting how often each user is logged in.

[johngg]

On Solaris who -q gives one or more lines of space-separated user names followed by a summary line giving total no. of users. I wonder what o/s chinamox is using.

Cheers,

JohnGG

[Anonymous Monk]

Not on my Solaris.

$ uname -a
SunOS mybox 5.8 Generic_108528-15 sun4u sparc SUNW,UltraAX-i2
$ /usr/bin/who -q
anomonk root
# users=2
$

[cephas]

Since it the question is already answered well, I'll answer small.

who|perl -e'$x{(split)[0]}++for(<>);print"$k => $v\n"while($k,$v)=each%x'

[Fletch]

Fore.

perl -le'$x{(split)[0]}++for(`who`);print"$k => $v"while($k,$v)=each%x
+'

Or

who|perl -lane'$x{$F[0]}++;END{print"$k => $v"while($k,$v)=each%x}'

[shmem]

who|perl -nle '/ /,$x{$`}++}{print"@l"while@l=each%x'

:-)

[cephas]

who|perl -nle'/ /,$;{$`}++}{print"@l"while@l=each%'

[cephas]

who|perl -ne'/ /,$;{$`}++}{print$_,$/^="*"for%'