Re: -pi -e argv repeater

[ikegami]

Perhaps you'd like

use constant PIE_NO_BACKUP => '';

sub pie(&$@) {
   (
      my $code,     # Code ref
      local $^I,    # PIE_NO_BACKUP, '~', '.bak', etc
      local @ARGV,
   ) = @_;

   local *_;     # Protect caller's $_.
   while (<>) {
      chomp;
      $code->();
      print($_, "\n");
   }
}

# perl -i -pe 's///' file1 file2
pie { s/// } PIE_NO_BACKUP, 'file1', 'file2';

# perl -i.bak -pe 's///' file? data*.txt
pie { s/// } '.bak', map { bsd_glob($_) } 'file?', 'data*.txt';

Untested.

Update: Added missing "\n". Created constant for no backup. Added local *_;.

[jettero]

$^I is apparently all I needed. I had no idea it would be so simple, thanks. I obviously should have just asked on the chatterbox... how embarassing.

[OfficeLinebacker]

May I ask what the (&$@) in the sub declaration is for?

[ikegami]

It's a prototype.

Without the prototype, you'd have to do
pie sub { CODE }, SCALAR, LIST
or
pie &func, SCALAR, LIST

With the prototype, you can also do
pie { CODE } SCALAR, LIST

[OfficeLinebacker]

Ikegami,
I see you disagree with Damian Conway (as expressed in Perl Best Practices--pp 194-196 for those of you following from home). I wish I understood better the exact thought processes behind each of your approaches.

Either way, yes, $^I is the way to go (or, if you really want to be a Boy Scout about it, use English, only without the evil regexp vars, and use $INPLACE_EDIT in place of $^I).