Re^4: how to loop

[rsiedl]

yep, that was the intended design. the scripts purpose is to randomly select a wallpaper and set it in gnome2. i can then add it to my startup scripts, and it'll change the wallpaper, either once at login, or continuously while i am logged in, depending upon what i've set $mode to.

i've modified it a bit more though, so maybe this makes more sense...

#!/usr/bin/perl

use strict;
use warnings;

use XML::Simple;

srand;

# Mode to run
my $mode = "startup";

# Interval to change at if we want $mode = "running"
my $interval = $ARGV[0];

# Change the mode if we have been passed an interval
$mode = "running" if ($interval);

# gconf vars
my $command = "gconftool-2";
my $gconf_item = "/desktop/gnome/background/picture_filename";

# The location of the background xml file
my $xmlfile = $ENV{HOME} . "/.gnome2/backgrounds.xml";

# Die if we dont have a background xml file
die("No backgrounds file [$xmlfile] found!") if (! -e $xmlfile);

# Find the current background so we dont change to this
my $current = `$command -g $gconf_item`;

# Read in the xml file contents to get our list of backgrounds
my $config = XMLin($xmlfile);

# Something to store our filenames in
my @backs;
foreach my $name (keys %{$config->{wallpaper}}) {

  # Skip any that have a deleted flag in the XML file
  next if ($config->{wallpaper}->{$name}->{deleted} eq "true");

  # Set the filename
  my $file = $config->{wallpaper}->{$name}->{filename};

  # Ignore the current background and the (none) background
  next if (($file eq $current) || ($file eq "(none)"));

  # Store the name in our array
  push(@backs, $file);

} # end-foreach

while (1) {

  # Get a random background from the array
  my $new = $backs[int(rand(@backs))];

  # Set the background to something new
  system($command . ' --type=string -s '. $gconf_item . ' \'' . $new .
+ '\'');

  # Break out of our while loop if mode ne "running"
  last if ($mode ne "running");

  # Sleep for some time
  sleep($interval*60);

} # end-while

exit;

[graff]

Yes, that does make more sense. Just one word of caution though... Instead of this:

    # Interval to change at if we want $mode = "running"
    my $interval = $ARGV[0];

    # Change the mode if we have been passed an interval
    $mode = "running" if ($interval);

something like this would be more prudent:

my $interval = 0;
if ( @ARGV ) {
    ( $interval ) = ( $ARGV[0] =~ /(\d+)/ )
        or die "Usage: $0 [m]\n m: number of minutes between color cha
+nges\n";
}
$mode = "running" if ( $interval );

That makes sure that you don't try to do arithmetic on a non-numeric string, or sleep for a negative number of seconds.

(update -- minor nit-pick -- since you now have an "interval" variable that is either true or false, you don't really need a "mode" variable, do you?)