Ordered hashes (Re: CRSC)

[tye]

You could always use Tie::IxHash for this. You can also cheat and do what I find myself doing sometimes:

my @pages = (
  welcome => \&page_welcome,
  address => \&page_address,
  recipients => \&page_recipients,
  preview => \&page_preview,
  done => \&page_done,
);
my %pages= @pages;
@pages= do { my $key= 0; grep { $key= !$key } @pages };

Since you have two hashes with shared keys, you might go a different route like:

my( @pageorder, %pages, %validators );
for(
    ["welcome", \&page_welcome, undef],
    ["address", \&page_address, \&validate_address],
    ["recipients", \&page_recipients, \&validate_recipients],
    ["preview", \&page_preview, undef],
    ["done", \&page_done, undef],
) {
    push @pageorder, $_->[0];
    $pages{$_->[0]}= $_->[1];
    $validators{$_->[0]}= $_->[2];
}

or perhaps:

use mapcar;
my( @pageorder, %pages, %validators );
BEGIN {
    my( $key, $page, $valid )= mapcar {[@_]}
      ["welcome", \&page_welcome, undef],
      ["address", \&page_address, \&validate_address],
      ["recipients", \&page_recipients, \&validate_recipients],
      ["preview", \&page_preview, undef],
      ["done", \&page_done, undef];
    @pageorder= @$keys;
    @pages{@$keys}= @$page;
    @validators{@$keys}= @$valid;
}

Season to taste.

        - tye (but my friends call me "Tye")