How Do I pass a hash to a subroutine?

[filmo]

How Do I pass a hash to a subroutine?

Originally posted as a Categorized Question.

[MeowChow]

Hashes can be passed either by value:

  mysub(%hash);

  sub mysub {
    my (%params) = @_;
  }

or by reference:

  mysub(\%hash);

  sub mysub {
    my $params = shift;
    my %paramhash = %$params;
  }

Each approach has it's advantages and disadvantages. Pass-by-value offers a simpler syntax, while pass by reference is faster and more flexible, allowing you to easily intermingle the hash with other parameters.

[nite_man]

Also, you can use prototypes to get special argument passing:


my_sub(%hash)

sub my_sub(\%) {
    my $hash_ref = shift;
    map { print "$_ => $$hash_ref{$_} \n" } keys %$hash_ref;
}

[Doraemon]

And, if you need to pass multiple parameters (eg. a hash and then an array) pass by reference; otherwise the hashes and arrays are flattened into a single list and the sub can't tell what is part of which.

Here is an example of using prototypes to force a pass-by-reference.

sub foo(\%\@)
{
   my ($hash_ref, $array_ref) = @_;
   #...
}

foo (%hash, @array);

[thephpguy]

MeowChow's code for passing by reference is VERY inefficient unless you actually want a copy of the Hash. (Why pass by ref if you want a copy?)

  mysub(\%hash);

  sub mysub {

    my $paramhash = $_[0];
  }

With the above code any modification will affect the original hash.

[GoldenSage]

New here, maybe more of an explaination of prototypes? Tried to use your routine of (\%) which had syntax error at the line (also created syntax errors along every @_ line called in the library I'm writting. Looked at prototypes (first time I've seen such) at Prototypes. Hasn't made since yet, appears certain functions being called. Does look like a neat solution if it works for me.

Originally posted as a Categorized Answer.

[GoldenSage]

ack.. ignore my previous post please, typo.. adn no edit button, however doesn't seem to have any values in the hash passed.

&formtable(%FORM);

sub formtable(\%) {
    my $hash_ref = shift;
    my %hash = %$hash_ref;
    foreach $key (%hash){
        print "$key=$hash{$key}";
    }
}# Close of formtable

prints nothing and I test the %FORM with same foreach loop and values print... ? globals? Have to use $_[0]??? etc.

[choroba]

Calling a subroutine with & ignores prototypes. Also, in order to make prototypes work, you must declare the subroutine before calling it.

Moreover, you are posting to the Answers section, while you probably wanted to reply to one of the answers.