working with non-delimited files

[semio]

fellow monks,

I'm working with a number of data files that have no defined delimiter. The goal is to take the data, delimit it into appropriate columns, and then insert the data into a db. I could obtain the required results via the following code, but I would like to shoot for something more succinct. Thanks in advance for any insights and suggestions for improvement. cheers!

#!/usr/bin/perl -w
use strict;
while (<DATA>) {
 my $line = $_;
 $line =~ s/\s+/\|/;
 $line =~ s/\s+/\|/;
 $line =~ s/\s+/\|/;
 $line =~ s/\s+/\|/;
 $line =~ s/\s+/\|/;
 print $line;
}
__DATA__
This#    is      stand alone data        "but this data needs to , sta
+y together/
and here is some more   -but this is a single column

..which produces the desired output:

This#|is|stand|alone|data|"but this data needs to , stay together/
and|here|is|some|more|-but this is a single column

[FunkyMonk]

I'd use split & join, rather than regex...

print join "|", split /\s+/, $_, 6
    for <DATA>

[runrig]

If the requirements are that the first five fields are space delimited, and the last field is the rest of the line, then just use the LIMIT argument of split:

my @fields = split " ", $line, 6;
print join("|", @fields);

Update: Hmm, I thought I read all the replies, but FunkyMonk already had it.

[blazar]

You want to know about the /g modifier. Read about it in perldoc perlre:

Update: on a second reading you probably want (code updated to reflect the change):

#!/usr/bin/perl

use strict;
use warnings;

while (my $line=<DATA>) {
    $line =~ s/\s+/|/ for 1..5;
    print $line;
}

__DATA__
This#    is      stand alone data        "but this data needs to , sta
+y together/
and here is some more   -but this is a single column

[FunkyMonk]

You've overwritten $_

Try

while (my $data = <DATA>) {
    $data =~ s/\s+/\|/ for 1..5;
    print $data;
}

Edit: Damn. Too Slow.

[blazar]

Edit: Damn. Too Slow.

You're right: I updated my node and said so. Then the update was wrong too, and I made a further update silently, in the hope that no one would notice... ;-) Of course you solution with split is far better, except that even for such a tiny thing I would use while instead of for. Until we're in full Perl 6 times, that is...