Re: XML::Twig question and problem

[mirod]

Question: is there some way to apply a filter to just the data and leave the tagging and attributes alone.

Look at the output_text_filter option, it filters only text and attribute values.

For your other problem, you can't use _default with print_roots, that just messes up everything. The output_text_filter thing will take care of it. And if you still have a problem with the beginning of the document being duplicated, get the development version of the module, I fixed a bug with it that last week.

[BenHopkins]

I saw that, but couldn't figure out how to use it.

If I say

...  output_text_filter => \%fixup,

and

sub fixup {
    my $t = $@;
    conv_chars(\$t); # subroutine that operates on a string
    return($t);
}

...doesn't work.

When I saymy $t = shift;, $t contains tag names.

I'm missing something here.

[mirod]

OK, so here the problem is that the filter opions do not operate when using the twig_print_outside_roots. At least they are not applied to the data outside the roots. Which makes sense as you are supposed to only care about what's inside the roots, that's the whole point of the "roots mode".

Below is a way of solving your problem. I must say I would not use it though. Instead I would do a pre or post processing of the data, using regexps or maybe Text::Unidecode, to replace the characters you don't want. I assume you want to replace those characters everywhere in the document, so most likely you don't need to use an XML aware tool.

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

my $t = XML::Twig->new( twig_handlers => { hl1 => \&fix_hl1,
                                           hl2 => \&fix_hl2,
                                           _all_ => \&fixup,
                                         }, 
                         keep_encoding => 1,
                         keep_spaces => 1,
                     )
                 ->parse( \*DATA);



sub fixup
  { my( $t, $elt)= @_;
    foreach my $pcdata ($elt->children( '#PCDATA'))
      { $pcdata->set_text( conv_chars( $pcdata->text)); } 
    $elt->flush unless( $_->in( 'hl1') || $_->in( 'hl2'));
  } 

sub conv_chars { my $t= shift; $t=~ s{—}{--}g; return $t; }
sub fix_hl1 { $_->set_tag( 'new_hl1')->prefix( 'fixed hl1:'); }
sub fix_hl2 { $_->set_tag( 'new_hl2')->prefix( 'fixed hl2:'); }

__DATA__
<!DOCTYPE nitf [
<!ENTITY foo "bar"> ]>
<nitf><s><hl1>hl1 with a &foo; and an other &foo; and &#8212; and &#82
+12;</hl1>
         <p>text, no foo</p>
         <p>text, no foo but &#8212;</p>
         <p>text, with &foo;</p>
         <hl2>hl2 with a &foo; and an other &foo; and &#8212; and &#82
+12;</hl2>
         <hl2>hl2 no foo </hl2>
         <hl2>hl2 with a bold <b>&foo;</b>, <b>&#8212;</b> and an othe
+r &foo;</hl2>
      </s>
</nitf>

[BenHopkins]

I see, I think. I was confusing roots mode with handlers mode. I was thinking I could do roots mode and handle 'outside roots' with a handler.

Another alternitive I was thinking was to slurp the document, and do a global search/replace before I did a parse.

Thanks, the more I learn about this module, the more I like it.