Regular expression

[Archana]

I have string like this for eg:- "Transcription factor" promoter DNA what i want is "Transcription factor",promoter,DNA. When i try to substitute for space in between the phrases("transcription factor") comma is substituted. how do i solve this problem?

[Samy_rio]

Hi Archana, try like this,

use strict;
use warnings;

my $str ='"Transcription factor" promoter DNA "Transcription factor" p
+romoter DNA.';
my @str = split//, $str;
my $fla = 1;
for (@str){
    if (($_ eq "\"") && $fla)
    {
        $fla = 0;
    }elsif (($_ eq "\"") && !($fla)){
        $fla = 1;
    }
    $_ =~ s/ /\,/ if ($fla);
}

print join'',@str;
__END__
Output:
-------
"Transcription factor",promoter,DNA,"Transcription factor",promoter,DN
+A.

TIMTOWTDI, we can achieve the expected output using RegExp as of below:

$str =~ s/((?:(?!\").)*)(\"[^\"]+\")((?:(?!\").)*)/
my $fi = $1;my $se = $2; my $th = $3;
$fi =~ s| |\,|g;$th =~ s| |\,|g;
"$fi$se$th"/egs;

[ikegami]

A tokenizer is what you want. Here's an implementation:

my $line ='"Transcription factor" promoter DNA';

my $fixed;
for ($line) {
   /\G ( \" [^"]+ \" ) /xgc && do { $fixed .= $1;  redo };
   /\G ( [^"\s]+     ) /xgc && do { $fixed .= $1;  redo };
   /\G   \s+           /xgc && do { $fixed .= ','; redo };
   last;
}

print("$fixed\n");