Re: Merged list with regex matches

[ikegami]

Fundametally you will need two nested loops, even if they are not obviously visible. (e.g. One could be hidden in a regexp.) However, it is possible to optimise the loops.

Possible optimisation one: Don't compile the same regexp over and over again:

for my $bn ( @B_CHECKS ) {
   my $re = qr/^(?:0|5|6)0+\Q$bn\E$/;
   for my $cn ( @CS_CHECKS ) {
      if ( $cn =~ $re ) {
         print "$bn = $cn\n";
      }
   }
}

Possible optimisation two: Create a single regexp:

my ($re) = map qr/^(?:0|5|6)0+($_)$/,
           join '|',
           map quotemeta,
           @B_CHECKS;

for my $cn ( @CS_CHECKS ) {
   if ( $cn =~ $re ) {
      print "$1 = $cn\n";
   }
}

Possible optimisation three: Create a single regexp using Regexp::List

use Regexp::List qw( ) 

my $re = Regexp::List->new->list2re(@B_CHECKS);
$re = qr/^(?:0|5|6)0+($re)$/;
for my $cn ( @CS_CHECKS ) {
   if ( $cn =~ $re ) {
      print "$1 = $cn\n";
   }
}

Possible optimisation four: Get rid of the regexp entirely, and do hash lookups. This will only work (as is) if $bn will never match /^(?:0|5|6)0+/.

my %B_CHECKS = map +($_ => 1), @B_CHECKS;
for my $cn ( @CS_CHECKS ) {
   (my $bn = $cn) =~ s/^(?:0|5|6)0+//;
   if ( $B_CHECKS{$bn} ) {
      print "$bn = $cn\n";
   }
}

Update: Added #3

[tcf03]

#4 Looks like what I need, I will need to double check that $bn will not match /^(0|5|6)0+/ These lists are fairly large so no matter what I do, Its going to be tough to speed up.
Thanks!