Counting number of characters in a string

[jeffpflueger]

Any quick tricks anyone has to simply counting the number of characters in a string? (I can think of some long ways to do this, but there must be a quicky)

Jeff Pflueger - Struggling Perl knowledge sponge

[chromatic]

length

[simul]

$cnt = @{[$str =~ /(\.)/g]};

[toolic]

This does not work for me. I expect the length of the string 'abc' to be 3, but your code returns 0:

use strict;
use warnings;

my $str = 'abc';
my $cnt = @{[$str =~ /(\.)/g]};
print "$cnt\n";

__END__
0

[Anonymous Monk]

hi all, counting number of characters is so easy.. use:length($stringname); $x=length($stringname);

[Rudif]

the shortest ones are the best
Rudif

[jcwren]

#!/usr/local/bin/perl -w
 
use strict;
 
{
   my $string = "Oh please, good sir program, what is my length?";
 
   printf ("The length is %d characters\n", howlong ($string));
 
   use Inline C => <<'END_OF_C_CODE';
 
   #include <string.h>
 
   int howlong(char *s)
   {
      return strlen (s);
   }
 
END_OF_C_CODE
}

--Chris

e-mail jcwren

[tye]

What do you have against nul bytes? (:

        - tye (but my friends call me "Tye")

[Anonymous Monk]

It didn't working

use strict;
 
{
   my $string = "Oh please, good sir program, what is my length?";
 
   printf ("The length is %d characters\n", howlong ($string));
 
   use Inline C => <<'END_OF_C_CODE';
 
   #include <string.h>
 
   int howlong(char *s)
   {
      return strlen (s);
   }
 
END_OF_C_CODE
}

[rowdog]

Works fine on Linux. I imagine you're missing either Inline::C or string.h and the associated library.

[japhy]

y cccc or (for 1 char shorter than length), y!!!c.

japhy -- Perl and Regex Hacker

[tilly]

my $len = map $_, $str =~ /(.)/gs;

[OeufMayo]

Yet Another (stupid) Way To Do It:

$string = "foobar";
$count = $string =~ s/(.)/$1/sg;

<kbd>--
my $OeufMayo = new PerlMonger::Paris({http => 'paris.mongueurs.net'});</kbd>

[tilly]

{
  $str =~ s/./\n/g;
  local $/ = "";
  $len = chomp($str);
}

[t0mas]

Yet Another Silly Way Of Counting Characters In A String (YASWOCCIAS):

$_="YASWOCCIAS";
s/./+1/g;
print eval;



/brother t0mas

[I0]

Shouldn't that be s/./+1/gs;

[t0mas]

$_="YASWOCCIAS"; don't contain any newlines so it doesn't matter in this case. In other cases it might, depending on how you define "character" in your application. For some apps (like word processors), s/\S/+1/g; might be the right choise if you like to use this algorithm in your production environment... :-)

/brother t0mas

[Falkkin]

$str =~ s/.*//;
print 0;

[japhy]

s/.*//s, silly.

japhy -- Perl and Regex Hacker

[tye]

my $count= 0;
for(0..255){
    my $c= pack "C", $_;
    $count += () = $str =~ /\Q$c\E/g;
}

Warning! This probably yields an inaccurate count for Unicode strings.

        - tye (but my friends call me "Tye")

[tye]

I just realized that most strings won't have most characters in them so this can be sped up significantly via:

my $count= 0;
for( keys %{ { map {$_,1} unpack "C*", $str } }  ){
    my $c= pack "C", $_;
    $count += () = $str =~ /\Q$c\E/g;
}

        - tye (but my friends call me "Tye")

[dfog]

my $String = "This is the way I do it";
my @Chars = split("", $String);
print ++$#Chars;

[sacked]

How about:

print scalar @Chars;

instead of:

print ++$#Chars;

Then you won't modify the array size.

--sacked

[archon]

sicker and twisteder!!

use strict;
use IPC::Open2;

my $pid = open2 (\*RDRFH, \*WTRFH, '/usr/bin/wc', '-c')
  or die "Couldn't open pipe to wc: $!";

if ($pid) {
  my $string = "shoes and ships and sealing wax";
  print WTRFH $string;
  close (WTRFH);
  my $len = <RDRFH>;
  $len =~ s/^\s+//;
  print "length: $len";
  close (RDRFH);
}

[petral]

Count the dots using a regular expression:

$str="There's many more ways to do it.\n";

$str =~ tr/\000-\xff/./;

while ( $str =~ /(.)/g ) {
   $count++;
}

You can check this using a different method:

$count2++ while chop $str;
$count eq $count2 or warn "there's something wrong with this code.\n";



p

[Anonymous Monk]

@arrayToReceiveChars = split(//,$varHoldingString); $len = @arrayToReceiveChars; print $len;

[Anonymous Monk]

if you're not in a subroutine, doing a split in scalar context: $length=split(//, $string) acheives the same thing. Don't do this in a subroutine though, or else you'll clobber your @_.