How do I read the files in @ARGV one by one

[Elias]

Of each dropped file, I would like to pass the filename first, and then the data, to an array. I have tried this:

 
foreach my $file (@ARGV) {
        push @data, substr($file, -12, 12);
        while (<>) {
                push (@data=>$_);
                }
}

However, it does not work: Only the first filename is pushed onto the array, followed by all the data in the files. Should I make a filehandle for each $file in @ARGV and loop the while statement over these filehandles? Is there another, more elegant solution?

[tilly]

How do you distinguish filenames from contents of files in your data structure? A hash of arrays is cleaner.

The following snippet should work:

$data{$_} = [] foreach @ARGV;
while (<>) {
  push @{$data{$ARGV}}, $_;
}

The purpose of the first line is to make sure that files which are empty are included in your hash.

[merlyn]

@ARGV = $_, push @data, $_, <> for @{[@ARGV]};

Hmm. There was some other clever trick to dup a list too, but I can't recall now.

-- Randal L. Schwartz, Perl hacker

---

update: Yeah, it's

@ARGV = $_, push @data, $_, <> for map $_, @ARGV;

[Masem]

Right now, you have no file handles to those data files to speak of, so it's odd how you are getting even that data. The way you want to do it is:

foreach my $file (@ARGV) {
    if ( -e $file ) {  # double check existence
        push @data, $file;
        open FILE , '<'.$file  or die $!;
        while( <FILE> ) { push @data, $_; } 
        close FILE;
    }
}

---

Dr. Michael K. Neylon - [e-mail] || "You've left the lens cap of your mind on again, Pinky" - The Brain

[isotope]

It's not odd because he's using the <> operator, which returns all the data from all the files listed in @ARGV, all in one pass, line by line. It doesn't let you break it up by file, though.

--isotope
http://www.skylab.org/~isotope/

[jeffa]

Personally, I prefer to just open a filehandle:

use IO::File;
my %files;
foreach my $name (@ARGV) {
    my $file = IO::File->new($name) or next; # print error message her
+e, etc.
    my @lines = <$file>;
    $files{$name} = \@lines;
    $file->close;
}

Jeff

R-R-R--R-R-R--R-R-R--R-R-R--R-R-R--
L-L--L-L--L-L--L-L--L-L--L-L--L-L--

[bjelli]

The trouble with your code is that <> does advanced magic: it reads in all the files on the command line line by line. You can find out which file you are reading right now by looking at $ARGV.

So for your little problem, you could remember what $ARGV was when you last read a line and check if $ARGV has changed:

my $OLDARGV;
while (<>) {
      push(@data, $ARGV) if $ARGV ne $OLDARGV;
      push(@data, $_);
      $OLDARGV=$ARGV;
}

But I admit that Masems code is probably easier to figure out.

--
Brigitte    'I never met a chocolate I didnt like'    Jellinek
http://www.horus.com/~bjelli/         http://perlwelt.horus.at

[merlyn]

OK, one other twisted way:

my @data = do {
  my @copy = @ARGV;
  local $/;
  map { shift @copy, map /(.*\n?)/g, $_ } <>;
};

-- Randal L. Schwartz, Perl hacker

[denishowe]

Make sure you don't do what I just did:

my @ARGV = $file;

The my creates a new, local @ARGV which is not what you want. Doh!

[busunsl]

Have a look at 'eof', it will tell you when a file ends.

perldoc -f eof

[tye]

I'd like to encourage you to check out the above advice.

Here is an alternative that I am becoming fond of:

my @data;
foreach my $file (@ARGV) {
    push @data, substr( $file, -12, 12 );
    local( *ARGV );
    @ARGV= ($file);
    push( @data, <> );
}

        - tye (but my friends call me "Tye")

[orbital]

You can also check into Getopt::Std or Getopt::Long, both of these modules give you more control over the command line. here is an example usage:

use Getopt::Long;

Configure( \%Config );
if( $Config{help} ){ Syntax(); exit();}

....Code Goes Here.....

sub Configure {

    my( $Config ) = @_;
    my $Result = 0;
    Getopt::Long::Configure( "prefix_pattern=(-|\/)" );
    $Result = GetOptions( $Config, 
                qw(
                       del|d=i
                    length|l=i
                    path|p=s
                    first|f=s
                    reports|r=i
                    help|?|h
                ) );
                
    if (! scalar $Config->{line}) { $Config->{line}=132;}
    if (! scalar $Config->{reports}) { $Config->{reports}=1;}
    if (! exists $Config->{path}) { Syntax(); exit; }
    if (! exists $Config->{first}) { Syntax(); exit; }
    
    if (exists $Config->{del}) { Delete(); }
    
    $stream = $Config->{line};
    $rptpag    = $Config->{reports};
    $dir = $Config->{path};
    $firstln = $Config->{first};
}

sub Syntax
{

    print <<EOT;

ansi.pl
-------
Used for Adding/Removing ANSI printer control characters.

Syntax:
    ansi.pl [-l length] [-p path] [-f first] [-r reports] [-d del]
    
        -l..........Defines length of each line in the files. [default
+=132]
        -p..........Specifies the directory path to process. [must be 
+defined]
                    (Directory must end with a \\)
        -f..........Defines the first line of a report. [must be defin
+ed]
        -r..........Set the number of reports per page. [default=1]
        -d..........Deletes defined number of characters from beginnin
+g of
                    each line. [optional]
        -h..........This help screen.            

        *(looks for all *.dat in specified directory, saves original t
+o *.bak)  


EOT

}