Extracting the number of %'s in a string

[mnranjeeth]

I have a string in the following format:
"-----%s----%a----%d--%s-%d---" ('-' can be anything).

I need to find out the
1. number of occurences %x (x is the character following the %) in the string
2. and the order in which they appear.

Is it possible to do it using a regex or is converting the string into an array and then processing it is the only way out?
If so what would be the most efficient way to do it?

[ikegami]

Should "%%a" count as one (x=%) or two (x=%,x=a)? The solution below returns the former.

my $count = my @order = $string =~ /%(.)/sg;

Or if you want the count for each different "x" instead of one global count:

$count{$_}++ for my @order = $string =~ /%(.)/sg;

Update: Added second solution.

[moritz]

use strict;
use warnings;
use Data::Dumper;

my @list = ("-----%s----%a----%d--%s-%d---" =~ m/\%./g);
print Dumper \@list;
__END__
$VAR1 = [
          '%s',
          '%a',
          '%d',
          '%s',
          '%d'
        ];

[pc88mxer]

while ($x =~ m/%(.)/g) {
  push(@order, $1);
  $count{$1}++;
}

At the end of the while loop, @order contains the order in which the %-codes were found, and %count contains the counts.

[poolpi]

my $s = "-----%s----%a----%d--%s-%d---";

print $s =~ tr/%//, "\n";   
 
print "$_\n" for ( $s =~ /%([ads])/g );

OUTPUT :
5
s
a
d
s
d

HTH,
PooLpi

[Zaxo]

To count them,

$_=q(aaa%bbbbb%cccccc%ddd);
print tr/%//, $/;

prints '3'

To extract their positions;

$_ = 'aaa%bbbbb%cccccc%ddd';
print $-[0], ' ' while /%/g;
print $/'

prints "3 9 16".

See perlvar for the @- array magic. You would push those values to an array, instead of printing, for further use.

[moritz]

The counting solution will give a wrong result if the string has a trailing %, because the OP wants the number of %s followed by another character.