Re: Default Hash Key

It can also be done using a tied hash (with a speed penalty). I don't see an existing module on CPAN after a quick look, but it's it's easy to write your own.

{
   package Hash::WithDefault;
   use Tie::Hash qw( );
   BEGIN { our @ISA = 'Tie::ExtraHash'; }

   use constant IDX_HASH    => 0;
   use constant IDX_DEFAULT => 1;
   use constant NEXT_IDX    => 2;

   sub FETCH {
      my ($self, $key) = @_;
      return ( exists( $self->[IDX_HASH]{$key} )
         ? $self->[IDX_HASH]{$key}
         : $self->[IDX_DEFAULT]
      );
   }
}


{
   tie my %hash, 'Hash::WithDefault', 'not in the alphabet';
   %hash = (
      a => 'a vowel',
      b => 'a consonant',
   );

   print("$_: $hash{$_}\n") for qw( a b ~ );
}
[download]

Output:

a: a vowel
b: a consonant
~: not in the alphabet
[download]

Comment on Re: Default Hash Key Select or Download Code

Replies are listed 'Best First'.
Re^2: Default Hash Key by alexm (Chaplain) on May 02, 2008 at 10:21 UTC
FYI, Hash-WithDefaults is already available on CPAN ;-)	[reply]
Re^3: Default Hash Key by ikegami (Patriarch) on May 02, 2008 at 21:48 UTC
Thanks for looking, but that module doesn't do what the OP wants as far as I can tell.	[reply]
Re^4: Default Hash Key by alexm (Chaplain) on May 03, 2008 at 09:35 UTC
That's true... I assumed it did from the NAME section description :-( I guess that `Hash::WithAlternatives` should've been a more appropiate name for that module.	[reply]
Re^5: Default Hash Key by Anonymous Monk on May 04, 2008 at 16:37 UTC
Re^6: Default Hash Key by alexm (Chaplain) on May 06, 2008 at 00:20 UTC
Re^5: Default Hash Key by Anonymous Monk on May 04, 2008 at 16:52 UTC
Re^6: Default Hash Key by alexm (Chaplain) on May 06, 2008 at 00:33 UTC
Re^2: Default Hash Key by jethro (Monsignor) on May 02, 2008 at 14:04 UTC
If I read the doc of Tie::Hash correctly, you should have used `use Tie::StdHash qw( );` [download] Tie::Hash only provides a subset of the necessary hash methods	[reply] [d/l]
Re^3: Default Hash Key by ikegami (Patriarch) on May 02, 2008 at 21:52 UTC
Tie::Hash, Tie::StdHash and Tie::ExtraHash are in Tie/Hash.pm, thus `use Tie::Hash;` is needed even if you want to use the Tie::StdHash class. `>perl -e"use Tie::StdHash qw( );" Can't locate Tie/StdHash.pm in @INC (@INC contains: c:/Progs/perl588/l +ib c:/Progs/perl588/site/lib .) at -e line 1. BEGIN failed--compilation aborted at -e line 1.` [download] Notice that I didn't actually inherit from Tie::Hash. I didn't inherit from Tie::StdHash either because it doesn't provide any means to store object attributes such as the default value. Tie::ExtraHash does.	[reply] [d/l] [select]


Problems? Is your data what you think it is?
	PerlMonks