Running code a certain amount of time

[Ninth Prince]

Hello Monks,

I would like to add a condition to a while loop that exits the loop if the code has been executing for certain amount of time. For example I would like the while to exit if ($count>100 or time>60 minutes). Is there a standard way for doing this? I don't need anything fancy. I just want to be able to set the program to run for a couple of hours (if need be) and then stop.

Thanks.

[ccn]

use alarm function and catch SIG{ALRM} signal

sub some_sub {
  eval {
    local $SIG{ALRM} = sub {die "died in SIG ALRM";};

    alarm(1);

    my $i=0;

    $i++ while 1;

    alarm(0);
  };
  if ($@) {
    if ($@ =~ /died in SIG ALRM/) {
      print "caught\n";
    }
    else {
      print $@;
    }
  }
}

[Limbic~Region]

Ninth Prince,
The example by ccn allows you to stop execution at almost any arbitrary point. What you haven't explained is what is going on inside the loop. Signals changed in 5.8 IIRC, so knowing if you want safe or unsafe signals is only something you can answer. There is an alternative if you want the code to exit the loop before starting the next loop (not anywhere in the middle of the loop).

my $limit = time + 3_600;
my $cnt;
while (1) {
    ++$cnt;
    last if $cnt > 100 || time > $limit;
    # rest of your loop
}

[blazar]

I just want to be able to set the program to run for a couple of hours (if need be) and then stop.

(additional emphasis by me)

I personally believe that for such prolonged times a solution along the lines of that suggested by L~R is best suited. Playing with alarm as duly suggested by ccn is more important in short lived situations in which finer control over time is needed and/or you need to timeout "no matter what" e.g. when running external processes:

Read more... (1157 Bytes)

Incidentally, it is worth reminding that for finer control over (not necessarily) short times a precious module would be Time::HiRes, which is in core.

[zentara]

See Roll your own Event-loop and setup a timer to exit. Or use one of the other event modules on cpan.

[mpeever]

If you're just trying to limit the number of iterations in your loop, something this simple will work:

my $iterations = 60;
while ( something_is_true  and $iterations-- ) {
  do_something();
}

[afresh1]

Deleted everything, since I was just agreeing with L~R. I swear I loaded the tab in the background before he posted and forgot to reload before posting. :-)