Removing first part of string with regex

[Anonymous Monk]

Dear all,

I have the following strings sample:

human.NT_113898
human.contig.1
human.2
human.IV

What I want to do is to remove word up to first period, and capturing the all after first period. Yielding:

NT_113898
contig.1
2
IV

How come my regex below doesn't work:

 /\.?(\S+)/;
print "$1\n";

What's the right way to do it?

[akho]

The ? makes the period optional, so your regex matches the whole word. /[^.]*\.(\S*)/ would work.

[ikegami]

You made the period optional. Get rid of the question mark.

/\.(\S+)/;
print "$1\n";

[linuxer]

I would use split() (with LIMIT) for this:

my ( $first, $rest ) = split m{\.}, $line, 2;

[pdcawley]

Let's rewrite your regular expression with the (?x) flag and comment it shall we? That gives us

qr{(?smx)
    \.?   # Match the first instance of 0 or 1 one periods
    (     # then capture
     \S+  # one or more non whitespace characters
    )
  }

So, if we follow that recipe on the string human.NT_113898, the matcher looks at the start of the string, sees that the test for 0 or 1 periods succeeds there, so it scarfs up the rest of the string into $1. Which isn't what you wanted. What you actually want depends a little on what you're expecting as input. Assuming that there's always going to be at least one period in the input string, something like

qr{(?smx)
   \.   # Find a full stop
   (.*) # and capture everything after it
  }

will do. However, f there's the possibility of there not being a period, you might have to do

qr{(?smx)
  ^      # From the beginning
  (?:    # In a group...
   [^.]* # Match any character except period, any number of times 
   \.    # followed by a period
  )?     # math the group 0 or 1 times
  (.*)   # then capture everything else
  }

If there's a trick to understanding why a regular expression doesn't do what you want, it's to break it down like this and go through each subexpression and explain to yourself what it's trying to match. Most of the time this narrative approach will lead you to your bug and to its fix remarkably quickly.

[andreas1234567]

Would /\w*\.(\S+)/ work? See perlre.

[sathiya.sw]

 /(\.?)(\S+)/;
 print ">$1<>$2<\n";

If you have modified your code like the above, then you could be able to understand by yourself that, first group does not matches anything, and it is an optional match.
All the input are matched by second group.

[balakrishnan]

U can also go by this,


open(FH,"1");
map {
    s/^[^.]*\.// && print;
} (<FH>);

[Anonymous Monk]

=) this should be as simple as $string =~ s/^\w+?\.//; Best regards, --les

[Anonymous Monk]

you can also use this

@array=('human.NT_113898','human.contig.1','human.2','human.IV');
foreach (@array)
{
if(/(\w+\.)(\w+|\d+|\.)/){print $2."\n";}
}