Re^2: "defined" in while loop Edit | Delete | Quote | Reply | Private Reply

[ikegami]

Also, it isn't necessary for $_ to be undefined (or unassigned) for the loop to end.

While that's true in general,

>perl -le"$_=4; while (--$_) { print }"
3
2
1

It's not true in this case.

>perl -e"print 0" | perl -le"while ($_ = <>) { print $_ ? 'true' : 'fa
+lse' }"
false

>perl -MO=Deparse -e"while (<>) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

>perl -MO=Deparse -e"while ($_ = <>) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

>perl -MO=Deparse -e"while (defined($_ = <>)) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

[ELISHEVA]

Thanks! Learn something every day! (well, lots today). But what is going on here? What (under the covers) makes this a special case? Why is Perl wrapping $_=<> in defined($_ =<>)? Another convenience feature? And where else does this happen?

Here's my output with a slightly expanded print line checking both the value and the defined status and just to make sure there was no monkey business with the special variable $_ I changed it to $line - same result as you, of course. (I had to switch " and ' to keep the bash shell from trying to resolve $_):

$  perl -e'print 0' | perl -e'while ($line = <>) { print "\$line=<$lin
+e> \$line=<" . ($line ? "true" : "false") . "> defined=<" . (defined(
+$line) ? "true" : "false") . ">\n"};'
$line=<0> $line=<false> defined=<true>

It is also not anything special about the syntax $somevar = <> because I get the same result if I use readline(...):

$ perl -e'print 0' | perl -e'while ($line = readline(*STDIN)) { print 
+"\$line=<$line> \$line=<" . ($line ? "true" : "false") . "> defined=<
+" . (defined($line) ? "true" : "false") . ">\n"};'
$line=<0> $line=<false> defined=<true>

Or is it? Could it be that both while($somevar = readline(...)) and while($somevar = <...>), but only these, have special semantics? I noticed that if I wrap readline in a function of my own that the special behavior goes away. For example,

use strict;
use warnings;

#The following all output:
#  BEFORE
#  $line=<0> $line=<false> defined=<true>
#  AFTER
#
# while (my $line = readline(*STDIN)) {
# while (my $line = <STDIN>) {
# while (my $line = <>) {
#
# but wrapping readline in a sub produces only
# BEFORE
# AFTER

print "BEFORE\n";
while (my $line = wrapped_readline(\*STDIN)) {
 print "\$line=<$line> \$line=<"
   . ($line ? "true" : "false") . "> defined=<"
   . (defined($line) ? "true" : "false") . ">\n";
}
print "AFTER\n";

sub wrapped_readline {
  my $fh = shift @_;
  my $sLine = readline($$fh);
  #print "wrapped_readline: <$sLine>\n";
  return $sLine;
}

Thanks in advance, beth

Update: refined question a bit; fixed error in sub of $_ with $line; added examples using readline and a sub wrapping readline.

[ikegami]

Another convenience feature?

Yes. It rarely matters, since most uses of <>/readline are for reading newline-terminated lines, which are necessarily true.

And where else does this happen?

It depends on your perception of "this". Perl does many things implicitly, but none other exactly like this.

It is also not anything special about the syntax $somevar = <> because I get the same result if I use readline(...)

It's not specific to the symtax, it's specific to the operator. <> (when used to read from a file) and readline are the same operator.

>perl -MO=Concise -e"my $fh; readline($fh)"
...
6     <1> readline[t2] vK/1 ->7
5        <0> padsv[$fh:1,2] ->6
-e syntax OK

>perl -MO=Concise -e"my $fh; <$fh>"
...
6     <1> readline[t2] vK*/1 ->7
5        <0> padsv[$fh:1,2] s ->6
-e syntax OK