how do you include multiple modules using one module

[diabelek]

Is there any way to include multiple modules using a single module. IE in C, you could have #include "my_common.h" which would have #include "file_a.h", #include "file_b.h"...

In perl, the only thing I can find that is comparable to write a line of code using eval, join and map but that still has to be written in every file.

We're looking for a solution that would let users do "use framework;" to include the whole framework we have written or chunks of it using qw(a b c). In our framework modules, we could use "use framework_common;" to include or common logging, constants, etc files.

[sweetblood]

Have a look at this thread Bundling commonly-used modules into a toolset I think it's just what you are looking for.
HTH

[xdg]

I.e. ToolSet

[weismat]

Have a look at Modern::Perl (http://search.cpan.org/~chromatic/Modern-Perl-1.03/lib/Modern/Perl.pm) - it imports several modules with one line.

[citromatik]

You can use Filter::Macro:

package framework

use Filter::Macro;

use strict;
use warnings;
use ...
....

1;

Then, a program or module that says use Filter::Macro will expand lines below use Filter::Macro into their own code

You can also take a look at Toolkit

[Anonymous Monk]

Exporter-

[doom]

Toolkit looks like it may be on the right track... but don't ignore the obvious, this sort of thing works:

package Module::DemoGroupExport;
#                                [e-mail]
#                                26 Feb 2009

=head1 NAME

Module::DemoGroupExport - repaces many "use" statements with one

=head1 SYNOPSIS

  use Module::DemoGroupExport qw( carp croak Dumper mkpath dirname );

  my $file = shift;
  my $loc  = dirname( $file );
  unless (-d $loc) {
   carp "Creating $loc...";
   mkpath( $loc ) or croak "Could not create $loc: $!";
  }

=head1 DESCRIPTION

Demonstration of a simple strategy for ganging together multiple
use statments for many Exporter-based modules into one, so that you
can replace many lines of commonly used "use" statements with a single
one.

Note: automatic exporting is now frowned upon -- better to explicitly
state what you want.

=head2 EXPORT

None by default.

=cut

use 5.8.0;
use strict;
use warnings;

use Carp           qw( carp cluck croak confess shortmess longmess );
use Data::Dumper   qw( Dumper );
use File::Path     qw( mkpath );
use File::Basename qw( fileparse basename dirname );
use File::Copy     qw( copy move );
use Cwd            qw( cwd abs_path );

require Exporter;

our @ISA = qw(Exporter);
our %EXPORT_TAGS = ( 'all' => [
  qw(
     carp cluck croak confess shortmess longmess
     Dumper
     mkpath
     fileparse basename dirname
     copy move
     cwd abs_path
    ) ] );

our @EXPORT_OK = ( @{ $EXPORT_TAGS{'all'} } );
our @EXPORT = qw(  ); # exported into callers namespace by default.
                      # (don't use this without a very good reason.)
our $VERSION = '0.01';

1;

=head1 SEE ALSO

  o  The cpan module L<Toolkit>

=head1 AUTHOR

Joseph Brenner, E<lt>[e-mail]<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2009 by Joseph Brenner

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.8.2 or,
at your option, any later version of Perl 5 you may have available.

=head1 BUGS

None reported... yet.

=cut