How to get the name from a reference

[michi]

Hello, i am looking for a way to get the "name" of a reference. I hope this example explains what i mean:

sub my_sub { print "hello\n"; }
my $var = 5;

my $subname = some_nice_function(\&my_sub); # should return 'main::my_
+sub'
my $varname = some_nice_function(\$var); # should return '$var' or 'va
+r'

I looking for a function (or any other way) that returns the string 'main::my_sub' if i pass a reference to my_sub. Is there any way to realize this?

[repellent]

As far as I know, we can only do it for CODE references:


# obtain CODEref name
use B;
sub coderef2name {
    my ($coderef) = @_;
    return unless UNIVERSAL::isa($coderef, "CODE");
    my $obj = B::svref_2object($coderef);
    return $obj->GV->STASH->NAME . "::" . $obj->GV->NAME;
}


Update: Changed to use GV->STASH->NAME instead.

Note that:


> perl -MDevel::Peek -e '$var = 123; Dump \$var; sub my_sub {}; Dump \
+&my_sub'
SV = RV(0x8073260) at 0x804cc28
  REFCNT = 1
  FLAGS = (TEMP,ROK)
  RV = 0x8065648
  SV = IV(0x8068920) at 0x8065648
    REFCNT = 2
    FLAGS = (IOK,pIOK)
    IV = 123
SV = RV(0x8073260) at 0x804cc28
  REFCNT = 1
  FLAGS = (TEMP,ROK)
  RV = 0x8064b34
  SV = PVCV(0x8061538) at 0x8064b34
    REFCNT = 2
    FLAGS = ()
    IV = 0
    NV = 0
    COMP_STASH = 0x804cb50    "main"
    START = 0x806d6a8 ===> 1053
    ROOT = 0x806fa68
    XSUB = 0x0
    XSUBANY = 0
    GVGV::GV = 0x8065684    "main" :: "my_sub"
    FILE = "-e"
    DEPTH = 0
    FLAGS = 0x0
    OUTSIDE_SEQ = 91
    PADLIST = 0x8064b04
    PADNAME = 0x804cce8(0x8088758) PAD = 0x8065678(0x805e5b0)
    OUTSIDE = 0x804cd78 (MAIN)

[chromatic]

Sub::Info is much easier.

[Fletch]

See the replies to How to de-reference a coderef?.

[Marshall]

I second ikegami's comment: what is the purpose?

With Perl there are amazing things that you can discover about what is going on in a sub. Just some simple example code is shown below. I am unsure as to what you want.

#!/usr/bin/perl -w
use strict;

print "testing main\n";
x();

sub x
{
  print "In sub x\n";
  print "   I am:           ", WHOamI(), "\n";
  SubLevel2();
}

sub SubLevel2
{
  print "in sub SubLevel2\n";
  print "   I am:           ", WHOamI(), "\n";
  print "   I was called by ", WHOwasI(),"\n";
}

sub WHOamI  { (caller(1))[3] };  #returns name of the 
                                 #sub that called this sub
sub WHOwasI { (caller(2))[3] };  #returns name of the parent of 
                                 #the sub that called this sub

__END__

#prints
testing main
In sub x
   I am:           main::x
in sub SubLevel2
   I am:           main::SubLevel2
   I was called by main::x

[ikegami]

What are you trying to accomplish?

[michi]

Thanks for your comments. I tried Sub::Info and noticed that this module uses Sub::Identify which does exactly what i need. :)
The reason why want to do this is that i need to send references to functions to other threads (with queues). Unfortunately its not possible to add strict CODE refs to a queue.

[Anonymous Monk]

Related module

Data::Dumper::Names - Dump variables with names (no source filter) using PadWalker

Sub::Information , what chromatic was talking about