xcol

[sflitman]

Category:

Utility Scripts

Description:

A simple text-based column extractor for use in Unix pipelines

#!/usr/bin/perl
# Stephen Flitman - extract one or more columns of a table
# Released under GPLv2
# Usage: ... | xcol N M ...
# where N, M, ... are 0-based column indices, and columsn are split by
+ tabs
# if invoked without arguments, tells you what columns are present and
+ their indices, useful if there is a header row

use strict;

if (@ARGV) {
   while (<STDIN>) {
      chop;
      my @fields=split(/\t/,$_);
      for (my $i=0; $i<=$#ARGV; $i++) {
         print $fields[$ARGV[$i]];
         print "\t" if $i<$#ARGV;
      }
      print "\n";
   }
} else {
   my $line;
   until ($line=~/\t/) { $line=<STDIN>; }
   chop $line;
   die "No lines to process" unless $line;
   my $i=0;
   for my $field (split(/\t/,$line)) {
      printf "%3d: $field\n",$i++;
   }
}

exit;

[graff]

How is this better than unix "cut"? I know it's different: "cut" uses 1-based column numbers instead of 0-based, and column selection requires a "-f" option flag, and when "-f" is not provided, it exits with usage instructions, instead of listing the fields on the first tab-delimited line of input. But to make it better:
• you might consider allowing options for selecting a delimiter other than tab (like "cut" does) -- e.g. the delimiter could be a regex (which is something "cut" can't do)
• you might also consider allowing the output field delimiter to be different from the input field delimiter (something else "cut" can't do)

I notice that you can output fields in arbitrary orders, and even output a given column more than once, and these are handy improvements over cut. But why stop there?

Minor nit-picks:

• don't use "chop" ("chomp" is better, but see below)
• given that it's only useful with piped input, die with usage instructions when STDIN is a tty (read about the "-t" function in "perldoc -f -X")
• it might also be nice to die with instructions when @ARGV contains things that aren't digit strings
• I like POD. Don't you?
• given a set of digit strings in @ARGV, your process could be expressed in less code:

  while (<STDIN>) {
      tr/\r\n//d;  # even better than chomp!
      print join( "\t", ( split /\t/ )[@ARGV] ), "\n";
  }
  

• (added as an update) BTW, this construct: until ($line=~/\t/) { $line=<STDIN>; } will be an infinite loop if the piped input never contains a tab character. I think you'll want this instead:

  while(<STDIN>) {
      last if /\t/;
  }
  die "No tab-delimited fields found\n" unless ( /\t/ );