Re^4: Golf: Improve this guy's fail . . . please!

[zhespelt]

I know it's not as elegant as the code above, but I think it's a bit better than my first one.

#!/usr/bin/perl -w

use strict;
use warnings;

local $/ = undef;

my $string = <>;
my @array = split(//, $string);

my %hash;
foreach (@array) {
    if ($_ =~ /\w/) {
        $hash{$_}++;
    }
}

my @keys = sort keys %hash;

my $total;
foreach (values %hash) {
    $total += $_;
}

foreach (@keys) {
    printf "%s\t%d\t%.3f\n", $_, $hash{$_}, $hash{$_}/$total;
}

print "$total characters\n";

[grinder]

This is lovely code. It has a nice balance between terseness and clarity.

Despite your baptism of fire, I hope you stay around. You'll learn a lot of stuff, not all necessarily about Perl.

[Boldra]

This code is a huge improvement, except for the variable names!

You started with names like $total_chars and %ascii_counts, and ended up with $total and %hash. %hash and @array are about the worst variable names you can use.

You've come a long way very quickly, and kudos for taking the criticism well.

[dragonchild]

I was hoping you'd come by. Welcome to the Monastery.

This is 100x better. Well-done. Variable names can be improved, but I can actually scan this code and understand the basic intent. The biggest improvement now would be to skip intermediate variables that only exist once. So, something like:

use strict;
use warnings FATAL => 'all';

use List::Utils qw( sum );

my $input = do {
    local $/;
    <>;
};

my %letters;
$letters{$_}++ for grep /\w/, split //, $input;

my $total = sum values %letters;

for ( sort keys %letters ) {
    printf "%s\t%d\t%.3f\n", $_, $letters{$_}, $letters{$_}/$total;
}

print "$total characters\n";

The big differences there are:
• Removing intermediate variables
• Scoping the localization of $/
• Using a module to do the summation
• Chaining functions in the grep split.
This would be considered more "perlish". Remember - readablity also includes conciseness. This is why well-written Java is less readable than well-written Perl.

[jwkrahn]

my %letters;
$letters{$_}++ for grep /\w/, split //, $input;

That would be simpler as:

my %letters;
$letters{$_}++ for $input =~ /\w/g;