Re^4: Check if Date interval contains Hour X

[ikegami]

contains wouldn't work, but intersects would

...| 20 | 21 | 22 | 23 | 00 | 01 | 02 | 03 |...
                  (------------)     log
                            (----]   hour
                            (--)     intersection

[alexm]

You're right again, I just realized a bit later so I've been playing with intersects:

sub hour_in_range {
    my ($dt_s, $dt_e, @hours) = @_;

    my $dt_span = DateTime::Span->from_datetimes(
        start => $dt_s, end => $dt_e
    );

    for my $hour (@hours) {
        my $dt = $dt_s->clone()
                      ->truncate( to => 'day' )
                      ->add( hours => $hour );

        $dt->add( days => 1 ) if $dt < $dt_s;

        my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, end => $dt
        );

        return 1 if $dt_span->intersects($hour_span);
    }

    return 0;
}

It's not as simple and efficient as your approach, but it shows how to use span intersection.

OTOH, I misunderstood the OP and was thinking that @hours = (1,11) was an interval (1am to 11am), not a list of hours to match.

[ikegami]

        my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, end => $dt
        );

should be

        my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, before => $dt->clone()->add( hours => 1 ),
        );

or the more readable

        my $hour_span = DateTime::Span->new(
            start => $dt, hours => 1,
        );

Update: No, neither fix help. They were suppose to make the following match:

2010-10-10 01:59:59|2010-10-10 01:59:59|blablalblabla

You need

sub hour_in_range {
    my ($dt_s, $dt_e, @hours) = @_;

    my $dt_span = DateTime::Span->from_datetimes(
        start => $dt_s, end => $dt_e
    );

    for my $hour (@hours) {
        my $dt = $dt_s->clone()
                      ->truncate( to => 'day' )
                      ->add( hours => $hour );

        my $dt_tomorrow = $dt->clone()->add( days => 1 );

        my $hour_span = DateTime::Span->new(
            start => $dt, hours => 1
        )->union( DateTime::Span->new(
            start => $dt_tomorrow, hours => 1
        ));

        return 1 if $dt_span->intersects($hour_span);
    }

    return 0;
}

And there you go, the four DateTimes per hour I mentioned earlier.

[alexm]

And there you go, the four DateTimes per hour I mentioned earlier.

Wow! I'm still a beginner with DateTime modules, and today I learnt a few things. Thanks a lot!