Re: Perl (specific) Algorithms?

[japhy]

Shell programmers are probably the most aware of the concept of a schwartzian transform. They get the results from something like ls -l, sort it somehow, and then use awk to extract a specific field.

Thanks to Perl's built-in hash data type, many idioms (such as intersection, union, and difference computation) are a snap:

@union = union(\@a, \@b);
@inter = intersection(\@a, \@b, \@c);
@diff  = difference(\@a, \@b);
@in_a  = unique_to(\@a, (\@b, \@c));


sub union {
  my %seen;
  @seen{@$_} = () for @_;
  return keys %seen;
}


sub intersection {
  my %seen;
  for (@_) { $seen{$_}++ for @$_ }
  return grep $seen{$_} == @_, keys %seen;
}


sub difference {
  my %seen;
  for (@_) { $seen{$_}++ for @$_ }
  return grep $seen{$_} == 1, keys %seen;
}


sub unique_to {
  my %seen;
  @seen{@{ shift() }} = ();
  delete @seen{@$_} for @_;
  return keys %seen;
}

Finding unique elements in a list is as easy as converting the list to the keys of a hash, and then extracting the keys again.

japhy -- Perl and Regex Hacker