Write code using less lines

[Anonymous Monk]

Hey there monks!
I need your wisdom in order to write the following snippet of code using less lines.
The purpose is to count only the letters (not the -) in the given string.
My way is:

$str='ABC---DR----EEEEEGGGG-GRE-RED----KKKK---';
$seq_no_dash=$str;
$seq_no_dash=~s/-//g;
$len_seq=length($seq_no_dash);

Can I do something in one-line perhaps?

[toolic]

Yes, you can do it in one line (instead of three). The following counts all non-dash characters, without modifying your original string :

use strict;
use warnings;

my $str='ABC---DR----EEEEEGGGG-GRE-RED----KKKK---';
my $len_seq = () = $str =~ /[^-]/g;

This is a FAQ:

perldoc -q count

See also:

• How can I count the number of occurrences of a substring within a string?
• Perl Idioms Explained - my $count = () = /.../g

[AR]

In addition, you could do:

my $len_seq = $str =~ tr/A-Za-z//;

[jwkrahn]

Or possibly:

my $len_seq = $str =~ tr/-//c;

[AnomalousMonk]

Another way, also without modification of the original string, perhaps slightly faster:

>perl -wMstrict -le
"my $str = 'ABC---DR----EEEEEGGGG-GRE-RED----KKKK---';
 print qq{'$str'};
 my $len = $str =~ tr/A-Za-z//;
 print qq{'$str'};
 print $len;
"
'ABC---DR----EEEEEGGGG-GRE-RED----KKKK---'
'ABC---DR----EEEEEGGGG-GRE-RED----KKKK---'
24

[johngg]

You can save a little typing and also be a little more comprehensive with respect to "anything not a dash" by using the c flag (complement) of tr, see Quote and Quote like Operators.

knoppix@Microknoppix:~$ perl -E '
> $str = q{ABC---DR----EEEEEGGGG-GRE-RED----KKKK---};
> $len_seq = $str =~ tr{-}{}c;
> say $len_seq;'
24
knoppix@Microknoppix:~$

I hope this is of interest.

[nagalenoj]

This will help you more.

[petdance]

Why is it important to use fewer lines?