Re^5: DWIM with non ASCII characters

[almut]

This only works because you have a UTF-8 terminal, but haven't told Perl about it.  In other words, Perl is treating the UTF-8 encoded byte sequence in the source code - which represents the Unicode char U+00F1 (ñ) - as two separate bytes, and passes them on as is (i.e. UTF-8 encoded) to the terminal, which consequently displays the character correctly.

Perl internally, however, you don't have a character string, so you cannot properly match, etc.:

#!/usr/local/bin/perl -l
use strict;
use warnings;
use Encode;

my $bytes = 'ñ';    # UTF-8 encoded source (c3 b1 = ñ)
                     # displays as two latin1 chars here (c3 = Ã, b1 =
+ ±), 
                     # because PM doesn't handle UTF-8

my $chars = decode('UTF-8', $bytes);

print '$bytes eq \x{f1} ? ', $bytes eq "\x{f1}" ? "match":"no match"; 
print '$chars eq \x{f1} ? ', $chars eq "\x{f1}" ? "match":"no match"; 

print '$bytes: ', $bytes;
print '$chars: ', $chars;

binmode STDOUT, "utf8";

print '$bytes (STDOUT is UTF-8): ', $bytes;
print '$chars (STDOUT is UTF-8): ', $chars;

The string comparison outputs:

$bytes eq \x{f1} ? no match
$chars eq \x{f1} ? match

and the byte/char values print as (in a UTF-8 terminal):

$bytes: ñ
$chars: 
$bytes (STDOUT is UTF-8): ñ
$chars (STDOUT is UTF-8): ñ

Note that as soon as you tell Perl that your terminal is UTF-8 (with binmode), the byte string stops printing correctly, because Perl is now converting the two byte/latin1 chars c3 and b1 to the respective UTF-8 sequences c3 83 and c2 b1, which display as two separate characters...

[Hue-Bond]

My output doesn't match yours, even when I do have the terminal in UTF-8. But that doesn't bug me since, as ikegami points out, the string lengths I get are wrong when I use non-ASCII characters:

$ perl -l
use warnings;
use strict;
print length 'ñ';
__END__
2

Now I wonder how is it possible that I've never encountered any problems with this :^). Thanks!